Hur konverterar jag snabbt siffror till engelska ord i Excel?

Att konvertera siffror till ord i Excel är användbart för att förbereda ekonomiska rapporter, juridiska dokument eller kontroller där du behöver stava belopp. Även om Excel inte erbjuder en inbyggd funktion för att konvertera siffror direkt till ord, finns det flera metoder du kan använda för att uppnå detta, allt från att använda ett Visual Basic for Applications (VBA) makro till tredjepartstillägg och online verktyg. Nedan kommer vi att utforska några av dessa metoder för att hjälpa dig hitta den bästa lösningen för dina behov.

• Konvertera nummer till valutor med användardefinierad funktion
• Konvertera siffror till valutor med en användbar funktion
• Konvertera nummer till engelska ord med användardefinierad funktion

Konvertera nummer till valutor med användardefinierad funktion

Om du vill konvertera siffrorna till engelska valutor bör du använda nedanstående VBA-kod.

1. Håll ner ALT + F11 knapparna och det öppnar Microsoft Visual Basic för applikationsfönster.

2. Klicka Insert > Modulernaoch klistra in följande kod i Modulfönster.

Function SpellNumberToEnglish(ByVal pNumber)
'Update by Extendoffice
Dim Dollars, Cents
arr = Array("", "", " Thousand ", " Million ", " Billion ", " Trillion ")
pNumber = Trim(Str(pNumber))
xDecimal = InStr(pNumber, ".")
If xDecimal > 0 Then
    Cents = GetTens(Left(Mid(pNumber, xDecimal + 1) & "00", 2))
    pNumber = Trim(Left(pNumber, xDecimal - 1))
End If
xIndex = 1
Do While pNumber <> ""
    xHundred = ""
    xValue = Right(pNumber, 3)
    If Val(xValue) <> 0 Then
        xValue = Right("000" & xValue, 3)
        If Mid(xValue, 1, 1) <> "0" Then
            xHundred = GetDigit(Mid(xValue, 1, 1)) & " Hundred "
        End If
        If Mid(xValue, 2, 1) <> "0" Then
            xHundred = xHundred & GetTens(Mid(xValue, 2))
        Else
            xHundred = xHundred & GetDigit(Mid(xValue, 3))
        End If
    End If
    If xHundred <> "" Then
        Dollars = xHundred & arr(xIndex) & Dollars
    End If
    If Len(pNumber) > 3 Then
        pNumber = Left(pNumber, Len(pNumber) - 3)
    Else
        pNumber = ""
    End If
    xIndex = xIndex + 1
Loop
Select Case Dollars
    Case ""
        Dollars = "No Dollars"
    Case "One"
        Dollars = "One Dollar"
    Case Else
        Dollars = Dollars & " Dollars"
End Select
Select Case Cents
    Case ""
        Cents = " and No Cents"
    Case "One"
        Cents = " and One Cent"
    Case Else
        Cents = " and " & Cents & " Cents"
End Select
SpellNumberToEnglish = Dollars & Cents
End Function
Function GetTens(pTens)
Dim Result As String
Result = ""
If Val(Left(pTens, 1)) = 1 Then
    Select Case Val(pTens)
        Case 10: Result = "Ten"
        Case 11: Result = "Eleven"
        Case 12: Result = "Twelve"
        Case 13: Result = "Thirteen"
        Case 14: Result = "Fourteen"
        Case 15: Result = "Fifteen"
        Case 16: Result = "Sixteen"
        Case 17: Result = "Seventeen"
        Case 18: Result = "Eighteen"
        Case 19: Result = "Nineteen"
        Case Else
    End Select
Else
Select Case Val(Left(pTens, 1))
    Case 2: Result = "Twenty "
    Case 3: Result = "Thirty "
    Case 4: Result = "Forty "
    Case 5: Result = "Fifty "
    Case 6: Result = "Sixty "
    Case 7: Result = "Seventy "
    Case 8: Result = "Eighty "
    Case 9: Result = "Ninety "
    Case Else
End Select
Result = Result & GetDigit(Right(pTens, 1))
End If
GetTens = Result
End Function
Function GetDigit(pDigit)
Select Case Val(pDigit)
    Case 1: GetDigit = "One"
    Case 2: GetDigit = "Two"
    Case 3: GetDigit = "Three"
    Case 4: GetDigit = "Four"
    Case 5: GetDigit = "Five"
    Case 6: GetDigit = "Six"
    Case 7: GetDigit = "Seven"
    Case 8: GetDigit = "Eight"
    Case 9: GetDigit = "Nine"
    Case Else: GetDigit = ""
End Select
End Function

3. Spara den här koden och gå tillbaka kalkylbladet, i en tom cell, ange denna formel = SpellNumberToEnglish (A2)( A2 är cellen du vill konvertera numret till ett engelska valutor) och dra sedan påfyllningshanteringen ner till cellerna som du vill använda denna formel, alla siffror har stavats till engelska valutor, se skärmdump:

Konvertera siffror till valutor med en användbar funktion

Stava ut siffror till ord utan ansträngning med Kutools för Excel! Oavsett om du behöver engelska valutauttryck eller tyska siffror, Kutools' Siffror till ord Funktionen stöder över 40 språk, vilket effektiviserar ditt arbetsflöde. Förenkla dina finansiella rapporter, juridiska dokument och mer genom att konvertera numeriska värden till exakta skrivna ord med bara några klick. Upptäck hur Kutools för Excel kan göra din databehandling snabbare och mer exakt. Prova det idag och upplev effektiviteten!

När du har installerat Kutools för Excel, gör så här:

1. Välj listan med siffror som du vill konvertera och klicka sedan på Kutools > Innehåll > Siffror till ord, se skärmdump:

2. I Siffror till valutaord dialogrutan, välj det språk du vill använda, här väljer jag Engelska alternativ från Språk listruta, se skärmdump:

3. Och klicka sedan på OK knappen kommer du att se alla siffror har stavats till engelska valutor:

tips: Om du bara vill ha de engelska orden, inte valutaord, vänligen kontrollera Omvandlas inte till valuta kryssrutan från Tillbehör avsnitt, se skärmdump:

Konvertera nummer till engelska ord med användardefinierad funktion

Det finns inga funktioner eller formler som kan hjälpa dig att lösa denna uppgift direkt i Excel, men du kan skapa en användardefinierad funktion för att slutföra den. Gör så här:

1. Håll ner ALT + F11 knapparna och det öppnar Microsoft Visual Basic för applikationsfönster.

2. Klicka Insert > Modulernaoch klistra in följande kod i Modulfönster.

Function NumberstoWords(ByVal MyNumber)
'Update by Extendoffice
Dim xStr As String
Dim xFNum As Integer
Dim xStrPoint
Dim xStrNumber
Dim xPoint As String
Dim xNumber As String
Dim xP() As Variant
Dim xDP
Dim xCnt As Integer
Dim xResult, xT As String
Dim xLen As Integer
On Error Resume Next
xP = Array("", "Thousand ", "Million ", "Billion ", "Trillion ", " ", " ", " ", " ")
xNumber = Trim(Str(MyNumber))
xDP = InStr(xNumber, ".")
xPoint = ""
xStrNumber = ""
If xDP > 0 Then
xPoint = " point "
xStr = Mid(xNumber, xDP + 1)
xStrPoint = Left(xStr, Len(xNumber) - xDP)
For xFNum = 1 To Len(xStrPoint)
xStr = Mid(xStrPoint, xFNum, 1)
xPoint = xPoint & GetDigits(xStr) & " "
Next xFNum
xNumber = Trim(Left(xNumber, xDP - 1))
End If
xCnt = 0
xResult = ""
xT = ""
xLen = 0
xLen = Int(Len(Str(xNumber)) / 3)
If (Len(Str(xNumber)) Mod 3) = 0 Then xLen = xLen - 1
Do While xNumber <> ""
If xLen = xCnt Then
xT = GetHundredsDigits(Right(xNumber, 3), False)
Else
If xCnt = 0 Then
xT = GetHundredsDigits(Right(xNumber, 3), True)
Else
xT = GetHundredsDigits(Right(xNumber, 3), False)
End If
End If
If xT <> "" Then
xResult = xT & xP(xCnt) & xResult
End If
If Len(xNumber) > 3 Then
xNumber = Left(xNumber, Len(xNumber) - 3)
Else
xNumber = ""
End If
xCnt = xCnt + 1
Loop
xResult = xResult & xPoint
NumberstoWords = xResult
End Function
Function GetHundredsDigits(xHDgt, xB As Boolean)
Dim xRStr As String
Dim xStrNum As String
Dim xStr As String
Dim xI As Integer
Dim xBB As Boolean
xStrNum = xHDgt
xRStr = ""
On Error Resume Next
xBB = True
If Val(xStrNum) = 0 Then Exit Function
xStrNum = Right("000" & xStrNum, 3)
xStr = Mid(xStrNum, 1, 1)
If xStr <> "0" Then
xRStr = GetDigits(Mid(xStrNum, 1, 1)) & "Hundred "
Else
If xB Then
xRStr = "and "
xBB = False
Else
xRStr = " "
xBB = False
End If
End If
If Mid(xStrNum, 2, 2) <> "00" Then
xRStr = xRStr & GetTenDigits(Mid(xStrNum, 2, 2), xBB)
End If
GetHundredsDigits = xRStr
End Function
Function GetTenDigits(xTDgt, xB As Boolean)
Dim xStr As String
Dim xI As Integer
Dim xArr_1() As Variant
Dim xArr_2() As Variant
Dim xT As Boolean
xArr_1 = Array("Ten ", "Eleven ", "Twelve ", "Thirteen ", "Fourteen ", "Fifteen ", "Sixteen ", "Seventeen ", "Eighteen ", "Nineteen ")
xArr_2 = Array("", "", "Twenty ", "Thirty ", "Forty ", "Fifty ", "Sixty ", "Seventy ", "Eighty ", "Ninety ")
xStr = ""
xT = True
On Error Resume Next
If Val(Left(xTDgt, 1)) = 1 Then
xI = Val(Right(xTDgt, 1))
If xB Then xStr = "and "
xStr = xStr & xArr_1(xI)
Else
xI = Val(Left(xTDgt, 1))
If Val(Left(xTDgt, 1)) > 1 Then
If xB Then xStr = "and "
xStr = xStr & xArr_2(Val(Left(xTDgt, 1)))
xT = False
End If
If xStr = "" Then
If xB Then
xStr = "and "
End If
End If
If Right(xTDgt, 1) <> "0" Then
xStr = xStr & GetDigits(Right(xTDgt, 1))
End If
End If
GetTenDigits = xStr
End Function
Function GetDigits(xDgt)
Dim xStr As String
Dim xArr_1() As Variant
xArr_1 = Array("Zero ", "One ", "Two ", "Three ", "Four ", "Five ", "Six ", "Seven ", "Eight ", "Nine ")
xStr = ""
On Error Resume Next
xStr = xArr_1(Val(xDgt))
GetDigits = xStr
End Function

3. Spara och stäng den här koden och gå tillbaka till kalkylbladet, i en tom cell, ange denna formel = Antal till ord (A2)( A2 är cellen du vill konvertera numret till ett engelska ord), se skärmdump:

4. Tryck sedan på ange och välj cell C2 och dra sedan fyllningshandtaget till det intervall som du vill innehålla denna formel. Alla de numeriska värdena har konverterats till motsvarande engelska ord.

Att välja rätt metod beror på dina preferenser och frekvensen av ditt behov av att konvertera siffror till ord i Excel. VBA erbjuder mest flexibilitet och integration inom Excel, medan tillägg kan ge en enklare lösning. Genom att följa dessa metoder kan du effektivt konvertera siffror till ord i ditt Excel-kalkylblad. Om du är intresserad av att utforska fler Excel-tips och tricks, erbjuder vår webbplats tusentals självstudier. Klicka här för att komma åt dem.