Hur skapar man en månads- / årskalender i Excel?
Under en tid måste du skapa en specifik månad eller årskalender i Excel, hur kan du snabbt lösa det? Denna handledning introducerar knep för att snabbt skapa månads- eller årskalender i Excel.
Skapa månads- eller årskalender med Excel-mall
Skapa enkelt månads- eller årskalender med Perpetual Calendar 
Skapa månads- eller årskalender med Excel-mall
I Excel kan du använda en kalendermall för att skapa en månads- eller årskalender.
1. Klicka på i Excel 2010/2013 Fil > Nya, i Excel 2007, klicka på Kontorsknapp > Nya, skriv sedan till höger i poppfönstret kalender in i sökmotorn. Se skärmdump:
I Excel 2010/2013
I Excel 2007
2. Tryck ange, sedan visas flera typer av kalendrar i fönstret. Välj en kalendertyp du behöver och klicka på Ladda ner (eller skapa) i den högra rutan. Se skärmdump:
Nu skapas en kalender i en ny arbetsbok. Se skärmdump:
Skapa månadskalender med VBA
Ibland måste du skapa en månadskalender för angiven månad, till exempel jan 2015. Det kan vara en kull som är svår att hitta en sådan kalendermall med ovanstående metod. Här introducerar jag en VBA-kod som hjälper dig att skapa en specifik månadskalender.
1. Tryck Alt + F11 nycklar för att öppna Microsoft Visual Basic för applikationer fönstret klickar Insert > Modulerna, kopiera och klistra sedan in under VBA-koden i fönstret.
VBA: Skapa månadskalender.
Sub CalendarMaker()
' Unprotect sheet if had previous calendar to prevent error.
ActiveSheet.Protect DrawingObjects:=False, Contents:=False, _
Scenarios:=False
' Prevent screen flashing while drawing calendar.
Application.ScreenUpdating = False
' Set up error trapping.
On Error GoTo MyErrorTrap
' Clear area a1:g14 including any previous calendar.
Range("a1:g14").Clear
' Use InputBox to get desired month and year and set variable
' MyInput.
MyInput = InputBox("Type in Month and year for Calendar ")
' Allow user to end macro with Cancel in InputBox.
If MyInput = "" Then Exit Sub
' Get the date value of the beginning of inputted month.
StartDay = DateValue(MyInput)
' Check if valid date but not the first of the month
' -- if so, reset StartDay to first day of month.
If Day(StartDay) <> 1 Then
StartDay = DateValue(Month(StartDay) & "/1/" & _
Year(StartDay))
End If
' Prepare cell for Month and Year as fully spelled out.
Range("a1").NumberFormat = "mmmm yyyy"
' Center the Month and Year label across a1:g1 with appropriate
' size, height and bolding.
With Range("a1:g1")
.HorizontalAlignment = xlCenterAcrossSelection
.VerticalAlignment = xlCenter
.Font.Size = 18
.Font.Bold = True
.RowHeight = 35
End With
' Prepare a2:g2 for day of week labels with centering, size,
' height and bolding.
With Range("a2:g2")
.ColumnWidth = 11
.VerticalAlignment = xlCenter
.HorizontalAlignment = xlCenter
.VerticalAlignment = xlCenter
.Orientation = xlHorizontal
.Font.Size = 12
.Font.Bold = True
.RowHeight = 20
End With
' Put days of week in a2:g2.
Range("a2") = "Sunday"
Range("b2") = "Monday"
Range("c2") = "Tuesday"
Range("d2") = "Wednesday"
Range("e2") = "Thursday"
Range("f2") = "Friday"
Range("g2") = "Saturday"
' Prepare a3:g7 for dates with left/top alignment, size, height
' and bolding.
With Range("a3:g8")
.HorizontalAlignment = xlRight
.VerticalAlignment = xlTop
.Font.Size = 18
.Font.Bold = True
.RowHeight = 21
End With
' Put inputted month and year fully spelling out into "a1".
Range("a1").Value = Application.Text(MyInput, "mmmm yyyy")
' Set variable and get which day of the week the month starts.
DayofWeek = WeekDay(StartDay)
' Set variables to identify the year and month as separate
' variables.
CurYear = Year(StartDay)
CurMonth = Month(StartDay)
' Set variable and calculate the first day of the next month.
FinalDay = DateSerial(CurYear, CurMonth + 1, 1)
' Place a "1" in cell position of the first day of the chosen
' month based on DayofWeek.
Select Case DayofWeek
Case 1
Range("a3").Value = 1
Case 2
Range("b3").Value = 1
Case 3
Range("c3").Value = 1
Case 4
Range("d3").Value = 1
Case 5
Range("e3").Value = 1
Case 6
Range("f3").Value = 1
Case 7
Range("g3").Value = 1
End Select
' Loop through range a3:g8 incrementing each cell after the "1"
' cell.
For Each cell In Range("a3:g8")
RowCell = cell.Row
ColCell = cell.Column
' Do if "1" is in first column.
If cell.Column = 1 And cell.Row = 3 Then
' Do if current cell is not in 1st column.
ElseIf cell.Column <> 1 Then
If cell.Offset(0, -1).Value >= 1 Then
cell.Value = cell.Offset(0, -1).Value + 1
' Stop when the last day of the month has been
' entered.
If cell.Value > (FinalDay - StartDay) Then
cell.Value = ""
' Exit loop when calendar has correct number of
' days shown.
Exit For
End If
End If
' Do only if current cell is not in Row 3 and is in Column 1.
ElseIf cell.Row > 3 And cell.Column = 1 Then
cell.Value = cell.Offset(-1, 6).Value + 1
' Stop when the last day of the month has been entered.
If cell.Value > (FinalDay - StartDay) Then
cell.Value = ""
' Exit loop when calendar has correct number of days
' shown.
Exit For
End If
End If
Next
' Create Entry cells, format them centered, wrap text, and border
' around days.
For x = 0 To 5
Range("A4").Offset(x * 2, 0).EntireRow.Insert
With Range("A4:G4").Offset(x * 2, 0)
.RowHeight = 65
.HorizontalAlignment = xlCenter
.VerticalAlignment = xlTop
.WrapText = True
.Font.Size = 10
.Font.Bold = False
' Unlock these cells to be able to enter text later after
' sheet is protected.
.Locked = False
End With
' Put border around the block of dates.
With Range("A3").Offset(x * 2, 0).Resize(2, _
7).Borders(xlLeft)
.Weight = xlThick
.ColorIndex = xlAutomatic
End With
With Range("A3").Offset(x * 2, 0).Resize(2, _
7).Borders(xlRight)
.Weight = xlThick
.ColorIndex = xlAutomatic
End With
Range("A3").Offset(x * 2, 0).Resize(2, 7).BorderAround _
Weight:=xlThick, ColorIndex:=xlAutomatic
Next
If Range("A13").Value = "" Then Range("A13").Offset(0, 0) _
.Resize(2, 8).EntireRow.Delete
' Turn off gridlines.
ActiveWindow.DisplayGridlines = False
' Protect sheet to prevent overwriting the dates.
ActiveSheet.Protect DrawingObjects:=True, Contents:=True, _
Scenarios:=True
' Resize window to show all of calendar (may have to be adjusted
' for video configuration).
ActiveWindow.WindowState = xlMaximized
ActiveWindow.ScrollRow = 1
' Allow screen to redraw with calendar showing.
Application.ScreenUpdating = True
' Prevent going to error trap unless error found by exiting Sub
' here.
Exit Sub
' Error causes msgbox to indicate the problem, provides new input box,
' and resumes at the line that caused the error.
MyErrorTrap:
MsgBox "You may not have entered your Month and Year correctly." _
& Chr(13) & "Spell the Month correctly" _
& " (or use 3 letter abbreviation)" _
& Chr(13) & "and 4 digits for the Year"
MyInput = InputBox("Type in Month and year for Calendar")
If MyInput = "" Then Exit Sub
Resume
End SubVBA kommer från den här webben https://support.microsoft.com/en-us/kb/150774
2. Tryck F5 nyckel eller Körning knappen, och en dialogruta dyker upp för att påminna dig om att skriva in den specifika månad du behöver för att skapa en kalender, se skärmdump:
3. klick OK. Nu skapas en kalender för januari 2015 i det aktiva arket.
Men i ovanstående metoder finns det vissa begränsningar, till exempel om du vill skapa en kalender från januari till maj på en gång måste du skapa kalendern fem gånger med ovanstående två metoder. Nu introducerar jag ett praktiskt verktyg för att lösa det snabbt och enkelt
Skapa enkelt månads- eller årskalender med Perpetual Calendar
Perpetual Calendar är ett av kraftfulla verktyg i Kutools för Excel, och det kan hjälpa dig att snabbt skapa månads- eller årskalender i Excel på en gång.
| Kutools för Excel, med mer än 300 praktiska funktioner, gör dina jobb enklare. | ||
1. klick Företag > Arbetsblad > Perpetual Calendar. se skärmdump:
2. I poppdialogrutan anger du månadslängden du vill skapa kalendern och klickar på Skapa. Se skärmdump:
Sedan skapas en ny arbetsbok med fem kalenderkalkylblad. Se skärmdump:
Dricks:
Om du bara vill skapa en specifik månadskalender behöver du bara välja samma månad både i textrutorna Från och Till i dialogrutan.
Klicka här om du vill veta mer om Perpetual Calendar
Bästa kontorsproduktivitetsverktyg
Uppgradera dina Excel-färdigheter med Kutools för Excel och upplev effektivitet som aldrig förr. Kutools för Excel erbjuder över 300 avancerade funktioner för att öka produktiviteten och spara tid. Klicka här för att få den funktion du behöver mest...
Fliken Office ger ett flikgränssnitt till Office och gör ditt arbete mycket enklare
- Aktivera flikredigering och läsning i Word, Excel, PowerPoint, Publisher, Access, Visio och Project.
- Öppna och skapa flera dokument i nya flikar i samma fönster, snarare än i nya fönster.
- Ökar din produktivitet med 50 % och minskar hundratals musklick för dig varje dag!
