Hur genererar eller listar jag alla möjliga permutationer i Excel?

Till exempel har jag tre tecken XYZ, nu vill jag lista alla möjliga permutationer baserat på dessa tre tecken för att få sex olika resultat som detta: XYZ, XZY, YXZ, YZX, ZXY och ZYX. I Excel, hur kan du snabbt generera eller lista alla permutationer baserat på olika antal tecken?

Generera eller lista alla möjliga permutationer baserat på tecken med VBA-kod

Generera eller lista alla möjliga permutationer baserat på tecken med VBA-kod

Följande VBA-kod kan hjälpa dig att lista alla permutationer baserat på ditt specifika antal bokstäver, gör så här:

1. Håll ner ALT + F11 nycklar för att öppna Microsoft Visual Basic för applikationer fönster.

2. Klicka Insert > Modulernaoch klistra in följande kod i Modulerna Fönster.

VBA-kod: Lista alla möjliga permutationer i excel

Sub GetString()
'Updateby Extendoffice
    Dim xStr As String
    Dim FRow As Long
    Dim xScreen As Boolean
    xScreen = Application.ScreenUpdating
    Application.ScreenUpdating = False
    xStr = Application.InputBox("Enter text to permute:", "Kutools for Excel", , , , , , 2)
    If Len(xStr) < 2 Then Exit Sub
    If Len(xStr) >= 8 Then
        MsgBox "Too many permutations!", vbInformation, "Kutools for Excel"
        Exit Sub
    Else
        ActiveSheet.Columns(1).Clear
        FRow = 1
        Call GetPermutation("", xStr, FRow)
    End If
    Application.ScreenUpdating = xScreen
End Sub
Sub GetPermutation(Str1 As String, Str2 As String, ByRef xRow As Long)
    Dim i As Integer, xLen As Integer
    xLen = Len(Str2)
    If xLen < 2 Then
        Range("A" & xRow) = Str1 & Str2
        xRow = xRow + 1
    Else
        For i = 1 To xLen
            Call GetPermutation(Str1 + Mid(Str2, i, 1), Left(Str2, i - 1) + Right(Str2, xLen - i), xRow)
        Next
    End If
End Sub

3. Tryck sedan på F5 nyckel för att köra den här koden, och en snabbruta visas för att påminna dig om att du anger de tecken som du vill lista alla permutationer, se skärmdump:

4. Efter att ha skrivit in tecknen och klicka sedan på OK -knappen visas alla möjliga permutationer i kolumn A i det aktiva kalkylbladet. Se skärmdump:

Anmärkningar: Om den angivna teckenlängden är lika med eller större än åtta tecken fungerar den här koden inte eftersom det finns för många permutationer.