Hur kan jag hitta och ersätta text och sedan bevara formatering i Excel?

Find and Replace-funktionen är kraftfull och användbar när vi behöver hitta ett specifikt värde och ersätta det med ett annat. Men om det finns en rad celler, och vissa av cellerna innehåller olika formateringsvärden. I det här fallet, för att hitta och ersätta värde med funktionen Sök och ersätt, kommer formateringen av värdena i celler att brytas enligt nedanstående skärmdump, hur kan vi bevara formateringen av värden i varje cell medan vi hittar och ersätter i Excel?

Hitta och ersätt bevara formatering med makrokod

Hitta och ersätt bevara formatering med makrokod

Det finns inga andra metoder men makrokod kan hjälpa dig att hitta och ersätta text och bevara formatering.

1. Tryck Alt + F11 nycklar för att öppna Microsoft Visual Basic för applikation fönster.

2. klick Insert > Modulernaoch klistra in under koden i skriptet.

VBA: Hitta och ersätt bevara formatering

Sub CharactersReplace(Rng As Range, FindText As String, ReplaceText As String, Optional MatchCase As Boolean = False)
  'UpdatebyExtendoffice20160711
    Dim I As Long
    Dim xLenFind As Long
    Dim xLenRep As Long
    Dim K As Long
    Dim xValue As String
    Dim M As Long
    Dim xCell As Range
    xLenFind = Len(FindText)
    xLenRep = Len(ReplaceText)
    If Not MatchCase Then M = 1
    For Each xCell In Rng
        If VarType(xCell) = vbString Then
            xValue = xCell.Value
            K = 0
            For I = 1 To Len(xValue)
              If StrComp(Mid$(xValue, I, xLenFind), FindText, M) = 0 Then
                xCell.Characters(I + K, xLenFind).Insert ReplaceText
                K = K + xLenRep - xLenFind
              End If
            Next
        End If
    Next
End Sub

Sub Test_CharactersReplace()
    Dim xRg As Range
    Dim xTxt As String
    Dim xCell As Range
    On Error Resume Next
    If ActiveWindow.RangeSelection.Count > 1 Then
      xTxt = ActiveWindow.RangeSelection.AddressLocal
    Else
      xTxt = ActiveSheet.UsedRange.AddressLocal
    End If
    Set xRg = Application.InputBox("Select a range:", "Kutools for Excel", xTxt, , , , , 8)
    If xRg Is Nothing Then Exit Sub
    Call CharactersReplace(xRg, "KK", "Kutools", True)
End Sub

Tips: I koden,  KK är strängen du vill hitta och Kutools är strängen du vill ersätta med, kan du ändra dem efter behov.

3. Tryck F5 nyckel, en dialogruta dyker upp för dig att välja ett område att hitta och ersätta, se skärmdump:

4. Klicka på OK och den specifika strängen i den valda cellen ersätts med annan och behåller formateringen.