Hur kör jag flera makron från högerklickmenyn i Excel?

Om det finns flera vba-makron i din arbetsbok bör du öppna VBA-fönstret och sedan välja makrot när du behöver köra koden. I den här artikeln vill jag prata om hur du kör makron från högerklickmenyn för att göra ditt arbete mer effektivt som vänster skärmdump visas.

Kör flera makron från högerklickmenyn med VBA-koder

Kör flera makron från högerklickmenyn med VBA-koder

För att köra makrokoderna i en arbetsbok från högerklickmenyn kan följande steg hjälpa dig, gör så här:

1. Hål ner Alt + F11 nycklar för att öppna Microsoft Visual Basic för applikationer fönster.

2. Dubbelklicka sedan Denna arbetsbok till vänster Projekt och kopiera sedan och klistra in nedanstående VBA-kod i den tomma modulen.

Private Sub Workbook_Open()
Run "LoadMacro"
End Sub
Private Sub Workbook_Activate()
Run "LoadMacro"
End Sub
Private Sub Workbook_Deactivate()
Run "ClearMacro"
End Sub
Private Sub Workbook_BeforeClose(Cancel As Boolean)
Run "ClearMacro"
ThisWorkbook.Save
End Sub

3. Fortfarande i Microsoft Visual Basic för applikationer klicka på fönstret Insert > Modulernaoch klistra in följande kod i den här modulen.

Private Sub LoadMacro()
Dim xArrMenu As Variant
Dim xStrLine, xSreBtnName As String
Dim xObjCBCF, xObjCntrAll As CommandBarControl
Dim xObjCBCs As CommandBars
Dim xObjCBBtn As CommandBarButton
Dim xIntLine, xFNum As Integer
Dim xObjComponent As Object
Run "ClearMacro"
Set xObjCBCF = Application.CommandBars("Cell").Controls.Add(msoControlPopup, before:=1)
xObjCBCF.Caption = " Run Macro "
xObjCBCF.BeginGroup = False
For Each xObjComponent In ActiveWorkbook.VBProject.VBComponents
    If xObjComponent.Type = 1 Then
        For xIntLine = 1 To xObjComponent.CodeModule.CountOfLines
        xStrLine = xObjComponent.CodeModule.Lines(xIntLine, 1)
        xStrLine = Trim(xStrLine)
            If (InStr(xStrLine, "()") > 0) And (Left(xStrLine, 11) = "Private Sub" Or Left(xStrLine, 3) = "Sub") Then
            xSreBtnName = ""
            If "Private Sub" = Left(xStrLine, 11) Then
                xSreBtnName = Trim(Mid(xStrLine, 12, InStr(xStrLine, "()") - 12))
            ElseIf "Sub" = Left(xStrLine, 3) Then
               xSreBtnName = Trim(Mid(xStrLine, 4, InStr(xStrLine, "()") - 4))
            End If
            If xSreBtnName <> "" And xSreBtnName <> "RightClickReset" And xSreBtnName <> "LoadMacro" And xSreBtnName <> "ActionMacro" Then
                Set xObjCBBtn = xObjCBCF.Controls.Add
                With xObjCBBtn
                    .FaceId = 186
                    .Style = msoButtonIconAndCaption
                    .Caption = xSreBtnName
                    .OnAction = "ActionMacro"
                End With
            End If
            End If
        Next xIntLine
    End If
Next xObjComponent
End Sub
Private Sub ClearMacro()
On Error Resume Next
CommandBars("Cell").Controls(" Run Macro ").Delete
Err.Clear
CommandBars("Cell").Reset
End Sub
Private Sub ActionMacro()
On Error GoTo Err1
With Application
Run .CommandBars("Cell").Controls(1).Controls(.Caller(1)).Caption
End With
Exit Sub
Err1:
    MsgBox "Invalid"
End Sub

4. När du har klistrat in koderna klickar du sedan på verktyg > ReferensprojektOch en Referenser-VBAProject dialogrutan visas och kontrollera sedan Microsoft Visual Basic för applikationsförlängning 5.3 alternativet i Tillgängliga referenser listruta, se skärmdump:

5. Klicka sedan OK För att stänga dialogrutan ska du nu spara den här arbetsboken som Excel Macro-Enabled Workbook format, se skärmdump:

6. Äntligen, starta om arbetsboken för att få kodeffekten, och nu när du högerklickar på en cell, a Kör makro alternativet infogas i högerklickmenyn och alla makron i din arbetsbok listas i undermenyn som följande skärmdump:

7. Sedan kan du köra koden bara genom att klicka på den.