Note: The other languages of the website are Google-translated. Back to English
Logga in  \/ 
x
or
x
Registrera  \/ 
x

or

VLOOKUP-funktion med några grundläggande och avancerade exempel i Excel

I Excel är VLOOKUP-funktionen en kraftfull funktion för de flesta Excel-användare, som används för att leta efter ett värde längst till vänster i dataområdet och returnera ett matchande värde i samma rad från en kolumn som du angav som nedan visas skärmdump. . Denna handledning talar om hur man använder VLOOKUP-funktionen med några grundläggande och avancerade exempel i Excel.

Innehållsförteckning:

1. Introduktion av VLOOKUP-funktionen - syntax och argument

2. Grundläggande VLOOKUP-exempel

3. Avancerade exempel på VLOOKUP

4. VLOOKUP-matchade värden behåller cellformatering

5. Ladda ner VLOOKUP-exempelfiler


Introduktion av VLOOKUP-funktionen - syntax och argument

Syntaxen för VLOOKUP-funktionen:

=VLOOKUP (lookup_value, table_array, col_index_num, [range_lookup])

argument:

Lookup_value: Det värde som du vill söka efter. Det måste vara i den första kolumnen i tabellen_array-intervallet.

Table_array: Dataintervallet eller tabellen där kolumnen för uppslagsvärde och kolumnen för resultatvärde lokaliseras.

Col_index_num: Antalet kolumner från vilket det matchade värdet kommer att returneras. Det börjar med 1 från kolumnen längst till vänster i tabellmatrisen.

Range_lookup: Ett logiskt värde som avgör om denna VLOOKUP-funktion returnerar en exakt matchning eller en ungefärlig matchning.

  • Ungefärlig matchning - 1 / SANT: Om en exakt matchning inte hittas söker formeln efter närmaste matchning - det största värdet som är mindre än uppslagsvärdet. I det här fallet bör du sortera uppslagskolumnen i stigande ordning.
    = VLOOKUP (lookup_value, table_array, col_index, TRUE)
    = VLOOKUP (lookup_value, table_array, col_index, 1)
  • Exakt matchning - 0 / FALSE: Detta används för att söka efter ett värde exakt lika med uppslagsvärdet. Om en exakt matchning inte hittas returneras felvärdet # N / A.
    = VLOOKUP (lookup_value, table_array, col_index, FALSE)
    = VLOOKUP (lookup_value, table_array, col_index, 0)

Anmärkningar:

  • 1. Vlookup-funktionen letar bara efter värde från vänster till höger.
  • 2. Om det finns flera matchande värden baserat på uppslagsvärdet returneras endast den första matchade med Vlookup-funktionen.
  • 3. Det returnerar felvärdet # Ej tillämpligt om uppslagsvärdet inte kan hittas.

Grundläggande VLOOKUP-exempel

1. Gör en exakt matchning Vlookup och ungefärlig matchning Vlookup

Gör en exakt matchning av Vlookup i Excel

Normalt, om du letar efter en exakt matchning med Vlookup-funktionen, behöver du bara använda FALSE i det senaste argumentet.

För att till exempel få motsvarande matematiska poäng baserat på specifika ID-nummer, gör så här:

1. Tillämpa formeln nedan i en tom cell där du vill få resultatet:

=VLOOKUP(F2,$A$2:$D$7,3,FALSE)

2. Och dra sedan påfyllningshandtaget ner till cellerna du vill fylla i denna formel, så får du resultatet efter behov. Se skärmdump:

Anmärkningar:

  • 1. I ovanstående formel, F2 är det värde som du vill returnera dess matchande värde, A2: D7 är tabellmatrisen, numret 3 är kolumnnumret som ditt matchade värde returneras från och FALSK hänvisar till den exakta matchningen.
  • 2. Om ditt kriterievärde inte finns i dataområdet visas ett felvärde # N / A.

Gör en ungefärlig matchning av Vlookup i Excel

Den ungefärliga matchningen är användbar för att söka värden mellan dataintervall. Om den exakta matchningen inte hittas kommer den ungefärliga Vlookup att returnera det största värdet som är mindre än uppslagsvärdet.

Till exempel, om du har följande intervalldata, finns de angivna orderna inte i kolumnen Order. Hur får du närmaste rabatt i kolumn B?

1. Ange följande formel i en cell där du vill placera resultatet:

=VLOOKUP(D2,$A$2:$B$9,2,TRUE)

2. Dra sedan fyllningshandtaget ner till cellerna för att tillämpa denna formel, så får du ungefärliga matchningar baserat på de angivna värdena, se skärmdump:

Anmärkningar:

  • 1. I ovanstående formel, D2 är det värde som du vill returnera dess relativa information, A2: B9 är dataområdet, numret 2 anger kolumnnumret som ditt matchade värde returneras och SANN hänvisar till den ungefärliga matchningen.
  • 2. Den ungefärliga matchningen returnerar det största värdet som är mindre än ditt specifika uppslagsvärde.
  • 3. För att använda Vlookup-funktionen för att få ett ungefärligt matchningsvärde måste du sortera den längst till vänster i dataområdet i stigande ordning, annars ger det fel resultat.

2. Gör en skiftlägeskänslig Vlookup i Excel

Som standard utför Vlookup-funktionen en skiftlägeskänslig uppslagning, vilket innebär att den behandlar gemener och versaler som identiska. Någon gång kan du behöva göra en skiftlägeskänslig uppslagning i Excel, funktionerna Index, Match och Exakt eller Lookup and Exact kan göra dig en tjänst.

Till exempel har jag följande dataintervall vilken ID-kolumn innehåller textsträng med versaler eller gemener, nu vill jag returnera motsvarande Math-poäng för det angivna ID-numret.

Formel 1: Använda EXAKT, INDEX, MATCH-funktioner

1. Ange eller kopiera nedanstående matrisformel till en tom cell där du vill få resultatet:

=INDEX($C$2:$C$10,MATCH(TRUE,EXACT(F2,$A$2:$A$10),0))

2. Tryck sedan på Ctrl + Skift + Enter tangenter samtidigt för att få det första resultatet, och välj sedan formelcellen, dra fyllningshandtaget ner till cellerna du vill fylla i denna formel, så får du rätt resultat du behöver. Se skärmdump:

Anmärkningar:

  • 1. I ovanstående formel, A2: A10 är kolumnen som innehåller de specifika värdena du vill slå upp i, F2 är uppslagsvärdet, C2: C10 är den kolumn där resultatet kommer att returneras.
  • 2. Om flera matchningar hittas kommer den här formeln alltid att returnera den första matchningen.

Formel 2: Använda Lookup och Exact-funktioner

1. Använd nedanstående formel i en tom cell där du vill få resultatet:

=LOOKUP(2,1/EXACT(F2,$A$2:$A$10),$C$2:$C$10)

2. Dra sedan påfyllningshandtaget ner till cellerna som du vill kopiera den här formeln, så får du matchade värden med skiftlägeskänslig enligt nedanstående skärmdump:

Anmärkningar:

  • 1. I ovanstående formel, A2: A10 är kolumnen som innehåller de specifika värdena du vill slå upp i, F2 är uppslagsvärdet, C2: C10 är den kolumn där resultatet kommer att returneras.
  • 2. Om flera matchningar hittas kommer den här formeln alltid att returnera den senaste matchningen.

3. Vlookup-värden från höger till vänster i Excel

Vlookup-funktionen letar alltid upp ett värde i kolumnen längst till vänster i ett dataområde och returnerar motsvarande värde från en kolumn till höger. Om du vill göra en omvänd Vlookup vilket innebär att leta upp ett visst värde till höger och returnera motsvarande värde i vänster kolumn som visas nedan:

Klicka för att veta detaljerna steg för steg om den här uppgiften ...


4. Vlookup det andra, nte eller sista matchande värdet i Excel

Normalt, om det finns flera matchande värden som hittas när du använder Vlookup-funktionen, kommer endast den första matchade posten att returneras. I det här avsnittet kommer jag att prata om hur man får det andra, n: e eller sista matchningsvärdet med Vlookup-funktionen.

Vlookup och returnera det andra eller nte matchande värdet

Anta att du har en lista med namn i kolumn A, den utbildning de köpte i kolumn B, och nu vill du hitta den andra eller nionde kursen som köpts av den givna kunden. Se skärmdump:

1. För att få det andra eller nte matchningsvärdet baserat på givna kriterier, använd följande matrisformel i en tom cell:

=INDEX($B$2:$B$14,SMALL(IF(E2=$A$2:$A$14,ROW($A$2:$A$14)-ROW($A$2)+1),2))

2. Tryck sedan på Ctrl + Skift + Enter tangenter tillsammans för att få det första resultatet och välj sedan formelcellen, dra fyllningshandtaget ner till cellerna du vill fylla denna formel och alla andra matchade värden baserade på de angivna namnen har visats på en gång, se skärmdump:

Notera:

  • I denna formel, A2: A14 är intervallet med alla värden för uppslag, B2: B14 är intervallet för de matchande värdena du vill returnera från, E2 är uppslagsvärdet och det sista numret 2 anger det andra matchade värdet du vill få, om du vill returnera det tredje matchande värdet behöver du bara ändra det till 3 som du behöver.

Vlookup och returnera det senaste matchande värdet

Om du vill söka efter och returnera det senaste matchande värdet enligt nedanstående skärmdump, detta Vlookup och returnera det senaste matchande värdet tutorial kan hjälpa dig att få det senaste matchande värdet i detaljer.


5. Vlookup-matchande värden mellan två angivna värden eller datum

Ibland kanske du vill söka värden mellan två värden eller datum och returnera motsvarande resultat enligt nedanstående skärmdump, i det här fallet kan du använda LOOKUP-funktionen och en sorterad tabell.

Vlookup matchande värden mellan två givna värden eller datum med formeln

1. Först bör din ursprungliga tabell vara ett sorterat dataintervall. Kopiera eller ange sedan följande formel i en tom cell:

=LOOKUP(2,1/($A$2:$A$6<=E2)/($B$2:$B$6>=E2),$C$2:$C$6)

2. Dra sedan fyllningshandtaget för att fylla denna formel till andra celler du behöver, och nu får du alla matchade poster baserat på det angivna värdet, se skärmdump:

Anmärkningar:

  • 1. I ovanstående formel, A2: A6 är intervallet för mindre värden och B2: B6 är intervallet för större nummer i ditt dataområde, E2 är det givna värdet som du vill få motsvarande värde, C2: C6 är kolumndata som du vill extrahera från.
  • 2. Denna formel kan också användas för att extrahera matchade värden mellan två datum enligt nedanstående skärmdump:

Vlookup matchar värden mellan två givna värden eller datum med en användbar funktion

Om du är smärtsam med ovanstående formel kommer jag här att introducera ett enkelt verktyg - Kutools för Excel, med dess LOOKUP mellan två värden kan du returnera motsvarande artikel baserat på det specifika värdet eller datumet mellan två värden eller datum utan att komma ihåg någon formel.   Klicka för att ladda ner Kutools för Excel nu!


6. Använda jokertecken för partiella matchningar i Vlookup-funktionen

I Excel kan jokertecken användas i Vlookup-funktionen, vilket gör att en partiell matchning utförs på ett sökningsvärde. Du kan till exempel använda Vlookup för att returnera matchat värde från en tabell baserat på en del av ett sökningsvärde.

Om jag antar att jag har en rad data som nedan visas skärmdump, nu vill jag extrahera poängen baserat på förnamnet (inte fullständigt namn). Hur kan man lösa denna uppgift i Excel?

1. Den normala Vlookup-funktionen fungerar inte korrekt, du behöver sammanfoga texten eller cellreferensen med ett jokertecken, vänligen kopiera eller ange följande formel i en tom cell:

=VLOOKUP(E2&"*", $A$2:$C$11, 3, FALSE)

2. Dra sedan fyllningshandtaget för att fylla denna formel till andra celler du behöver, och alla matchade poäng har returnerats enligt nedanstående skärmdump:

Anmärkningar:

  • 1. I ovanstående formel, E2 & ”*” är uppslagsvärdet, värdet i E2 och den * jokertecken (“*” anger ett tecken eller tecken), A2: C11 är uppslagsområdet, numret 3 kolumnen som innehåller värdet som ska returneras.
  • 2. Vlookup när du använder jokertecken måste du ställa in exakt matchningsläge med FALSE eller 0 för det sista argumentet i Vlookup-funktionen.

Tips:

1. Hitta och returnera matchande värden som slutar med ett visst värde, använd denna formel: =VLOOKUP("*"&E2, $A$2:$C$11, 3, FALSE)

2. För att leta upp och returnera det matchade värdet baserat på en del av textsträngen, oavsett om den angivna texten finns framför, bakom eller i mitten av textsträngen, behöver du bara sammanfoga två * tecken runt cellreferensen eller texten. Vänligen gör med den här formeln: =VLOOKUP("*"&D2&"*", $A$2:$B$11, 2, FALSE)


7. Vlookup-värden från ett annat kalkylblad

Vanligtvis kan du behöva arbeta med mer än ett kalkylblad, Vlookup-funktionen kan användas för att slå upp data från ett annat ark som samma som på ett kalkylblad.

Till exempel har du två kalkylblad som visas nedan i skärmdumpen, för att leta upp och returnera motsvarande data från kalkylbladet du angav, gör med följande steg:

1. Ange eller kopiera formeln nedan till en tom cell där du vill få matchade objekt:

=VLOOKUP(A2,'Data sheet'!$A$2:$C$15,3,0)

2. Dra sedan påfyllningshandtaget ner till cellerna som du vill använda denna formel, så får du motsvarande resultat som du behöver, se skärmdump:

Notera: I ovanstående formel:

  • A2 representerar uppslagsvärdet;
  • Datablad är namnet på kalkylbladet som du vill söka efter data från, (Om arkets namn innehåller mellanslag eller skiljetecken, bör du bifoga enstaka citat runt arkets namn, annars kan du använda arkets namn direkt som = VLOOKUP (A2, Datablad! $ A $ 2: $ C $ 15,3,0));
  • A2: C15 är utbudet av data i databladet där vi söker efter data;
  • antalet 3 är kolumnnumret som innehåller matchade data som du vill returnera från.

8. Vlookup-värden från en annan arbetsbok

Detta avsnitt kommer att prata om uppslag och returnera matchande värden från en annan arbetsbok med hjälp av Vlookup-funktionen.

Till exempel innehåller den första arbetsboken produkt- och kostnadslistor, nu vill du extrahera motsvarande kostnad i den andra arbetsboken baserat på produktobjektet enligt nedanstående skärmdump.

1. För att hämta den relativa kostnaden från en annan arbetsbok, öppna först båda arbetsböckerna du vill använda och använd sedan följande formel i en cell där du vill placera resultatet:

=VLOOKUP(B2,'[Product list.xlsx]Sheet1'!$A$2:$B$6,2,0)

2. Dra och kopiera sedan denna formel till andra celler du behöver, se skärmdump:

Anmärkningar:

  • 1. I ovanstående formel:
    B2 representerar uppslagsvärdet;
    [Produktlista.xlsx] Ark1 är namnet på arbetsboken och kalkylbladet som du vill söka efter data från, (Hänvisningen till arbetsboken finns inom hakparenteser och hela arbetsboken + arket bifogas i enstaka citat);
    A2: B6 är utbudet av data i kalkylbladet i en annan arbetsbok där vi söker efter data;
    antalet 2 är kolumnnumret som innehåller matchade data som du vill returnera från.
  • 2. Om sökarbetsboken är stängd kommer hela filsökvägen för sökarbetsboken att visas i formeln enligt följande skärmdump:

9. Vlookup och returnera tom eller specifik text istället för 0 eller # N / A felvärde

Normalt, när du använder vlookup-funktionen för att returnera motsvarande värde, om din matchande cell är tom, kommer den att returnera 0, och om ditt matchande värde inte hittas, får du ett fel # N / A-värde som visas nedan. Istället för att visa 0 eller # N / A-värdet med tom cell eller annat värde du gillar, detta Vlookup ska returnera tomt eller specifikt värde istället för 0 eller ej tillämpligt tutorial kan göra dig en tjänst steg för steg.


Avancerade exempel på VLOOKUP

1. Tvåvägssökning med Vlookup-funktion (Vlookup i rad och kolumn)

Ibland kan du behöva göra en tvådimensionell uppslagning, vilket innebär att Vlookup i både rad och kolumn samtidigt. Låt oss säga, om du har följande dataområde och nu kan du behöva få värdet för en viss produkt i ett angivet kvartal. Detta avsnitt kommer att introducera en formel för att hantera detta jobb i Excel.

Formel 1: Använda VLOOKUP- och MATCH-funktioner

I Excel kan du använda en kombination av VLOOKUP- och MATCH-funktioner för att göra en tvåvägssökning, använd följande formel i en tom cell och tryck sedan ange för att få resultatet.

=VLOOKUP(H1, $A$2:$E$6, MATCH(H2, $A$1:$E$1, 0), FALSE)

Notera: I ovanstående formel:

  • H1: uppslagsvärdet i kolumnen som du vill få motsvarande värde baserat på;
  • A2: E6: dataområdet inklusive radrubriker;
  • H2: uppslagsvärdet i raden som du vill få motsvarande värde baserat på;
  • A1: E1: cellerna i kolumnrubriker.

Formel 2: Använda INDEX- och MATCH-funktioner

Här är en annan formel som också kan hjälpa dig att utföra en tvådimensionell uppslagning, använd nedanstående formel och tryck sedan på ange för att få det resultat du behöver.

=INDEX($B$2:$E$6, MATCH(H1, $A$2:$A$6, 0), MATCH(H2, $B$1:$E$1, 0))

Notera: I ovanstående formel:

  • B2: E6: dataområdet för att returnera det matchade objektet från;
  • H1: uppslagsvärdet i kolumnen som du vill få motsvarande värde baserat på;
  • A2: A6: radrubrikerna innehåller den produkt du vill leta efter.
  • H2: uppslagsvärdet i raden som du vill få motsvarande värde baserat på;
  • B1: E1: kolumnrubrikerna innehåller det kvartal du vill leta efter.

2. Vlookup-matchningsvärde baserat på två eller flera kriterier

Det är lätt för dig att slå upp matchningsvärdet baserat på ett kriterium, men om du har två eller flera kriterier, vad kan du göra? Funktionerna LOOKUP eller MATCH och INDEX i Excel kan hjälpa dig att lösa detta jobb snabbt och enkelt.

Till exempel har jag nedanstående datatabell, för att returnera det matchade priset baserat på den specifika produkten och storleken kan följande formler hjälpa dig.

Formel 1: Använd LOOKUP-funktionen

Använd nedanstående formel i en cell där du vill få resultatet och tryck sedan på Enter-tangenten, se skärmdump:

=LOOKUP(2,1/($A$2:$A$12=G1)/($B$2:$B$12=G2),($D$2:$D$12))

Anmärkningar:

  • 1. I ovanstående formel:
    A2: A12 = G1: betyder att söka efter kriterierna för G1 inom intervallet A2: A12;
    B2: B12 = G2: betyder att söka efter kriterierna för G2 inom intervallet B2: B12;
    D2: D12: det intervall som du vill returnera motsvarande värde.
  • 2. Om du har mer än två kriterier behöver du bara gå med i de andra kriterierna i formeln, till exempel: =LOOKUP(2,1/($A$2:$A$12=G1)/($B$2:$B$12=G2)/($C$2:$C$12=G3),($D$2:$D$12))

Formel 2: Använda INDEXT- och MATCH-funktioner

Kombinationen av index- och matchningsfunktion kan också användas för att returnera det matchade värdet baserat på flera kriterier. Vänligen kopiera eller skriv in följande formel:

=INDEX($D$2:$D$12,MATCH(1,($A$2:$A$12=G1)*($B$2:$B$12=G2),0))

Tryck sedan på Ctrl + Skift + Enter-tangenterna tillsammans för att få det relativa värdet som du behöver. Se skärmdump:

Anmärkningar:

  • 1. I ovanstående formel:
    A2: A12 = G1: betyder att söka efter kriterierna för G1 inom intervallet A2: A12;
    B2: B12 = G2: betyder att söka efter kriterierna för G2 inom intervallet B2: B12;
    D2: D12: det intervall som du vill returnera motsvarande värde.
  • 2. Om du har mer än två kriterier behöver du bara gå med i de nya kriterierna i formeln, till exempel: =INDEX($D$2:$D$12,MATCH(1,($A$2:$A$12=G1)*($B$2:$B$12=G2)*($C$2:$C$12=G3),0))

3. Vlookup för att returnera flera matchande värden med ett eller flera villkor

I Excel söker Vlookup-funktionen efter ett värde och returnerar bara det första matchningsvärdet om det finns flera motsvarande värden. Ibland kanske du vill returnera alla motsvarande värden i en rad, i en kolumn eller i en enda cell. Detta avsnitt kommer att prata om hur du returnerar flera matchande värden med en eller flera villkor i en arbetsbok.

Vlookup alla matchande värden baserat på ett eller flera villkor horisontellt

Vlookup alla matchande värden baserat på ett villkor horisontellt:

För att Vlookup och returnera alla matchande värden baserat på ett visst värde horisontellt är den generiska formeln:

=IFERROR(INDEX(return_range, SMALL(IF(lookup_value = lookup_range, ROW(return_range) - m, ""), COLUMN() - n)), "")
Anmärkningar: m är radnumret för den första cellen i returområdet minus 1.
      n är kolumnnumret för den första formelcellen minus 1.

1. Använd formeln nedan i en tom cell och tryck sedan på Ctrl + Skift + Enter knappar tillsammans för att få det första matchade värdet, se skärmdump:

=IFERROR(INDEX($C$2:$C$20, SMALL(IF($F1=$A$2:$A$20, ROW($C$2:$C$20)-1,""), COLUMN()-5)),"")

2. Välj sedan den första formelcellen och dra fyllningshandtaget till höger celler tills tom cell visas och alla motsvarande objekt har extraherats, se skärmdump:

Tips:

Om det finns dubbla matchade värden i den returnerade listan, använd dessa formler för att ignorera dubbletterna och tryck sedan på ange för att få det första resultatet: =IFERROR(INDEX($C$2:$C$20,MATCH($F1,$A$2:$A$20,0)),"")

Fortsätt med att skriva in denna formel: =IFERROR(INDEX($C$2:$C$20,MATCH(1,($F1=$A$2:$A$20)*ISNA(MATCH($C$2:$C$20,$F2:F2,0)),0)),"") in i en cell bredvid det första resultatet och tryck sedan på Ctrl + Skift + Enter tangenter tillsammans för att få det andra resultatet, dra sedan denna formel till rätt celler för att få alla andra matchade värden tills tom cell visas, se skärmdump:


Vlookup alla matchande värden baserat på två eller flera villkor horisontellt:

Till Vlookup och returnera alla matchande värden baserat på mer specifika värden horisontellt är den generiska formeln:

=IFERROR(INDEX(return_range, SMALL(IF(1 = ((--(lookup_value1=lookup_range1)) * (--(lookup_value2 = lookup_range2))), ROW(return_range) - m, ""), COLUMN() - n)),"")
Anmärkningar: m är radnumret för den första cellen i returområdet minus 1.
      n är kolumnnumret för den första formelcellen minus 1.

1. Tillämpa följande formel i en tom cell där du vill skicka resultatet:

=IFERROR(INDEX($C$2:$C$20, SMALL(IF(1=((--($F1=$A$2:$A$20)) * (--($F2=$B$2:$B$20))), ROW($C$2:$C$20)-1,""), COLUMN()-5)),"")

2. Välj sedan formelcellen och dra fyllningshandtaget till höger celler tills tom cell visas, och alla matchade värden baserat på de specifika kriterierna har returnerats, se skärmdump:

Anmärkningar: För fler kriterier behöver du bara gå med i lookup_value och lookup_range i formeln, till exempel: =IFERROR(INDEX(return_range, SMALL(IF(1 = ((--(lookup_value1=lookup_range1)) * (--(lookup_value2 = lookup_range2) * (--(lookup_value3 =lookup_range3)))), ROW(return_range) - m, ""), COLUMN() - n)),"").


Vlookup alla matchande värden baserat på ett eller flera villkor vertikalt

Vlookup alla matchande värden baserat på ett villkor vertikalt:

För att Vlookup och returnera alla matchande värden baserat på ett visst värde vertikalt är den generiska formeln:

=IFERROR(INDEX(return_range, SMALL(IF(lookup_value = lookup_range, ROW(return_range )- m ,""), ROW() - n )),"")
Anmärkningar: m är radnumret för den första cellen i returområdet minus 1.
      n är radnumret för den första formelcellen minus 1.

1. Kopiera eller skriv följande formel i en cell där du vill få resultatet och tryck sedan på Ctrl + Skift + Enter knappar tillsammans för att få det första matchade värdet, se skärmdump:

=IFERROR(INDEX($C$2:$C$20, SMALL(IF(E$2=$A$2:$A$20, ROW($C$2:$C$20)-1,""), ROW()-1)),"")

2. Välj sedan den första formelcellen och dra fyllningshandtaget ner till andra celler tills tom cell visas och alla motsvarande objekt har listats i en kolumn, se skärmdump:

Tips:

För att ignorera dubbletterna i de returnerade matchande värdena, använd dessa formler: =IFERROR(INDEX($C$2:$C$20,MATCH(0,COUNTIF($F$1:F1,$C$2:$C$20)+($A$2:$A$20<>$E$2),0)),"")

Tryck sedan på Ctrl + Skift + Enter tangenter tillsammans för att få det första matchade värdet och dra sedan formelcellen ner till andra celler tills tom cell visas, så får du resultatet efter behov:


Vlookup alla matchande värden baserat på två eller flera villkor vertikalt:

För att Vlookup och returnera alla matchande värden baserat på mer specifika värden vertikalt är den generiska formeln:

=IFERROR(INDEX(return_range, SMALL(IF(1=((--(lookup_value1=lookup_range1)) * ( --(lookup_value2=lookup_range2))), ROW(return_range)-m,""), ROW()-n)),"")
Anmärkningar: m är radnumret för den första cellen i returområdet minus 1.
      n är radnumret för den första formelcellen minus 1.

1. Kopiera nedanstående formel till en tom cell och tryck sedan på Ctrl + Skift + Enter för att få det första matchade objektet.

=IFERROR(INDEX($C$2:$C$20, SMALL(IF(1=((--($E$2=$A$2:$A$20)) * (--($F$2=$B$2:$B$20))), ROW($C$2:$C$20)-1,""), ROW()-1)),"")

2. Dra sedan formelcellen ner till andra celler tills tom cell visas, se skärmdump:

Anmärkningar: För fler kriterier behöver du bara gå med i lookup_value och lookup_range i formeln, till exempel: =IFERROR(INDEX(return_range, SMALL(IF(1 = ((--(lookup_value1=lookup_range1)) * (--(lookup_value2 = lookup_range2) * (--(lookup_value3 =lookup_range3)))), ROW(return_range) - m, ""), ROW() - n)),"").


Vlookup alla matchande värden baserat på två eller flera villkor i en cell

Om du vill Vlookup och returnera flera matchade värden i en enda cell med angiven avgränsare kan den nya funktionen TEXTJOIN hjälpa dig att lösa detta jobb snabbt och enkelt.

Vlookup alla matchande värden baserat på ett villkor i en cell:

Använd den enkla formeln nedan i en tom cell och tryck sedan på Ctrl + Skift + Enter knappar tillsammans för att få resultatet:

=TEXTJOIN(",",TRUE,IF($A$2:$A$20=F1,$C$2:$C$20,""))

Tips:

För att ignorera dubbletterna i de returnerade matchande värdena, använd dessa formler: =TEXTJOIN(",", TRUE, IF(IFERROR(MATCH($C$2:$C$20, IF(F1=$A$2:$A$20, $C$2:$C$20, ""), 0),"")=MATCH(ROW($C$2:$C$20), ROW($C$2:$C$20)), $C$2:$C$20, ""))


Vlookup alla matchande värden baserade på två eller flera villkor i en cell:

För att hantera flera villkor när du returnerar alla matchande värden till en enda cell, använd nedanstående formel och tryck sedan på Ctrl + Skift + Enter knappar tillsammans för att få resultatet:

=TEXTJOIN(",",TRUE,IF(($A$2:$A$20=F1)*($B$2:$B$20=F2),$C$2:$C$20,""))

Anmärkningar:

1. TEXTJOIN-funktionen är endast tillgänglig i Excel 2019 och Office 365.

2. Om du använder Excel 2016 och tidigare versioner, använd den användardefinierade funktionen i artiklarna nedan:


4. Vlookup för att returnera hela eller hela raden i en matchad cell

I det här avsnittet kommer jag att prata om hur man hämtar hela raden med ett matchat värde med hjälp av Vlookup-funktionen.

1. Kopiera eller skriv in formeln nedan i en tom cell där du vill skicka resultatet och tryck ange för att få det första värdet.

=VLOOKUP($F$2,$A$1:$D$12,COLUMN(A1),FALSE)

2. Dra sedan formelcellen till höger tills data för hela raden visas, se skärmdump:

Anmärkningar: I ovanstående formel, F2 är det uppslagsvärde du vill returnera hela raden baserat på, A1: D12 är det dataområde du vill använda, A1 anger det första kolumnnumret inom ditt dataområde.

Tips:

Om flera rader hittas baserat på det matchade värdet, använd denna formel för att returnera alla motsvarande rader: =IFERROR(INDEX(A:A,SMALL(IF(ISNUMBER(SEARCH($F$2,$A$2:$A$12)),ROW($A$2:$A$12),""),ROW()-1)),""), och tryck sedan på Ctrl + Skift + Enter tangenterna tillsammans för att få det första resultatet, dra sedan fyllningshandtaget rätt till cellerna, se skärmdump:

Och dra sedan påfyllningshandtaget ner över cellerna för att få alla matchande rader som visas nedan:


5. Gör flera Vlookup-funktioner (kapslade Vlookup) i Excel

Ibland kanske du vill slå upp värden i flera tabeller, om någon av tabellerna innehåller det angivna uppslagsvärdet enligt nedanstående skärmdump, i det här fallet kan du kombinera en eller flera Vlookup-funktioner tillsammans med IFERROR-funktionen för att utföra flera uppslag.

Den generiska formeln för kapslad Vlookup-funktion är:

=IFERROR(VLOOKUP(lookup_value,table1,col,0),IFERROR(VLOOKUP(lookup_value,table2,col,0),VLOOKUP(lookup_value,table3,col,0)))

Notera:

  • letauppvärde: det värde du letar efter;
  • Table1, Table2, Table3, ...: tabellerna i vilka uppslagsvärde och returvärde finns;
  • col: kolumnnumret i tabellen som du vill returnera matchande värde från.
  • 0: Detta används för en exakt matchning.

1. Använd följande formel i en tom cell där du vill placera resultatet:

=IFERROR(VLOOKUP(J3,$A$3:$B$7,2,0),IFERROR(VLOOKUP(J3,$D$3:$E$7,2,0),VLOOKUP(J3,$G$3:$H$7,2,0)))

2. Dra sedan fyllningshandtaget ner till cellerna som du vill använda den här formeln och alla matchade värden har returnerats enligt nedanstående skärmdump:

Anmärkningar:

  • 1. I ovanstående formel, J3 är det värde du letar efter; A3: B7, D3: E7, G3: H7 är tabellområdena i vilka uppslagsvärde och returvärde finns; Numret 2 är kolumnnumret i intervallet att matcha värdet från.
  • 2. Om uppslagsvärdet inte kan hittas visas ett felvärde för att ersätta felet med en läsbar text, använd denna formel: =IFERROR(VLOOKUP(J3,$A$3:$B$7,2,0),IFERROR(VLOOKUP(J3,$D$3:$E$7,2,0),IFERROR(VLOOKUP(J3,$G$3:$H$7,2,0),"can't find")))

6. Vlookup för att kontrollera om värdet finns baserat på listdata i en annan kolumn

Vlookup-funktionen kan också hjälpa dig att kontrollera om värden finns baserat på en annan lista, till exempel om du vill leta efter namnen i kolumn C och bara returnera Ja eller Nej om namnet hittas eller inte i kolumn A som nedan skärmdump visad.

1. Använd följande formel i en tom cell:

=IF(ISNA(VLOOKUP(C2,$A$2:$A$10,1,FALSE)), "No", "Yes")

2. Dra sedan påfyllningshandtaget ner till cellerna som du vill fylla i denna formel, så får du resultatet efter behov, se skärmdump:

Anmärkningar: I ovanstående formel, C2 är uppslagsvärdet du vill kontrollera; A2: A10 är listan med intervall från vilken sökvärden kommer att hittas; numret 1 är kolumnnumret varifrån du vill hämta värde i ditt intervall.


7. Vlookup och summera alla matchade värden i rader eller kolumner

Om du arbetar med numeriska data, ibland när du extraherar matchade värden från tabellen, kan du också behöva summera siffrorna i flera kolumner eller rader. I det här avsnittet presenteras några formler för att slutföra detta jobb i Excel.

Vlookup och summera alla matchade värden i en rad eller flera rader

Antag att du har en produktlista med försäljning i flera månader som nedan visas skärmdump, nu måste du summera alla beställningar under alla månader baserat på de angivna produkterna.

Vlookup och summera de första matchade värdena i rad:

1. Kopiera eller skriv in följande formel i en tom cell och tryck sedan på Ctrl + Skift + Enter för att få det första resultatet.

=SUM(VLOOKUP(H2, $A$2:$F$9, {2,3,4,5,6}, FALSE))

2. Dra sedan ned fyllningshandtaget för att kopiera den här formeln till andra celler du behöver, och alla värden i en rad med det första matchande värdet har summerats tillsammans, se skärmdump:

Anmärkningar: I ovanstående formel: H2 är cellen som innehåller det värde du letar efter; A2: F9 är dataområdet (utan kolumnrubriker) som inkluderar uppslagsvärdet och de matchade värdena; Numret 2,3,4,5,6 {} är kolumnnummer som används för att beräkna totala intervallet.


Vlookup och summera alla matchade värden i flera rader:

Ovanstående formel kan bara summera värden i rad för det första matchade värdet. Om du vill summera alla matchningar i flera rader, använd följande formel och dra sedan fyllningshandtaget ner till cellerna du vill använda denna formel, så får du önskat resultat du behöver, se skärmdump:

=SUMPRODUCT(($A$2:$A$9=H2)*$B$2:$F$9)

Anmärkningar: I ovanstående formel: H2 är det sökvärde du letar efter; A2: A9 är radrubrikerna som innehåller uppslagsvärdet; B2: F9 dataområdet för de numeriska värdena som du vill summera.


Vlookup och summera alla matchade värden i en kolumn eller flera kolumner

Vlookup och summera de första matchade värdena i en kolumn:

Om du vill summera det totala värdet för de specifika månaderna som visas på skärmdumpen nedan.

Tillämpa nedanstående formel i en tom cell och dra sedan ned fyllningshandtaget för att kopiera den här formeln till andra celler, nu har de första matchade värdena baserade på den specifika månaden i en kolumn summerats, se skärmdump:

=SUM(INDEX($B$2:$F$9,0,MATCH(H2,$B$1:$F$1,0)))

Anmärkningar: I ovanstående formel: H2 är det sökvärde du letar efter; B1: F1 är kolumnrubrikerna som innehåller sökningsvärdet; B2: F9 dataområdet för de numeriska värdena som du vill summera.


Vlookup och summera alla matchade värden i flera kolumner:

För att Vlookup och summera alla matchade värden i flera kolumner, bör du använda följande formel:

=SUMPRODUCT($B$2:$F$9*(($B$1:$F$1)=H2))

Anmärkningar: I ovanstående formel: H2 är det sökvärde du letar efter; B1: F1 är kolumnrubrikerna som innehåller sökningsvärdet; B2: F9 dataområdet för de numeriska värdena som du vill summera.


Vlookup och summera de första matchade eller alla matchade värdena med en kraftfull funktion

Kanske ovanstående formler är svåra för dig att komma ihåg, i det här fallet rekommenderar jag en praktisk funktion - Sökning och summa of Kutools för Excel, med den här funktionen kan du få resultatet så enkelt som möjligt.    Klicka för att ladda ner Kutools för Excel nu!


Vlookup och summera alla matchade värden både i rader och kolumner

Om du vill summera värdena när du till exempel måste matcha både kolumn och rad för att få det totala värdet av produkten Tröja i mars som visas nedan.

Använd följande formel i en cell och tryck sedan på Enter för att få resultatet, se skärmdump:

=SUMPRODUCT(($B$2:$F$9)*($B$1:$F$1=I2)*($A$2:$A$9=H2))

Anmärkningar: I ovanstående formel: B2: F9 är dataområdet för de numeriska värdena som du vill summera; B1: F1 is kolumnrubrikerna innehåller det sökningsvärde som du vill summera baserat på; I2 är uppslagsvärdet i kolumnrubrikerna du letar efter; A2: A9 är radrubrikerna innehåller det sökningsvärde som du vill summera baserat på; H2 är uppslagsvärdet i de radrubriker du letar efter.


8. Vlookup för att slå samman två tabeller baserat på en eller flera nyckelkolumner

I ditt dagliga arbete, när du analyserar data, kan du behöva samla all nödvändig information i en enda tabell baserat på en eller flera nyckelkolumner. För att lösa detta jobb kan Vlookup-funktionen också göra dig en tjänst.

Vlookup för att slå samman två tabeller baserat på en nyckelkolumn

Till exempel har du två tabeller, den första tabellen innehåller data om produkter och namn, och den andra tabellen innehåller produkter och order. Nu vill du kombinera dessa två tabeller genom att matcha den gemensamma produktkolumnen i en tabell.

Formel 1: Använda VLOOKUP-funktionen

För att slå samman de två tabellerna i en baserad på en nyckelkolumn, använd följande formel i en tom cell där du vill få resultatet och dra sedan påfyllningshandtaget ner till cellerna som du vill använda denna formel, du kommer att få en sammanslagen tabell med orderkolumnen som går med i den första tabelldata baserat på nyckelkolonndata.

=VLOOKUP($A2,$E$2:$F$8,2,FALSE)

Anmärkningar: I ovanstående formel, A2 är det värde du letar efter, E2: F8 är tabellen att söka, numret 2 är kolumnnumret i tabellen som värdet ska hämtas från.

Formel 2: Använda INDEX- och MATCH-funktioner

Om dina vanliga data på höger sida och de returnerade uppgifterna i den vänstra kolumnen i den andra tabellen, för att slå samman orderkolumnen, kan inte Vlookup-funktionen göra jobbet. För att titta upp från höger till vänster kan du använda funktionerna INDEX och MATCH för att ersätta Vlookup-funktionen.

Vänligen kopiera eller skriv in formeln nedan i en tom cell, kopiera sedan formeln ner i kolumnen och ordningskolumnen har kopplats till den första tabellen, se skärmdump:

=INDEX($E$2:$E$8, MATCH($A2, $F$2:$F$8, 0))

Anmärkningar: I ovanstående formel, A2 är det sökvärde du letar efter, E2: E8 är ett utbud av data som du vill returnera, F2: F8 är sökningsområde som innehåller sökningsvärdet.


Vlookup för att slå samman två tabeller baserat på flera nyckelkolumner

Om de två tabellerna som du vill gå med har flera nyckelkolumner, för att slå samman tabellerna baserat på dessa vanliga kolumner, kan funktionerna INDEX och MATCH hjälpa dig.

Den generiska formeln för att slå samman två tabeller baserat på flera nyckelkolumner är:

=INDEX(lookup_table, MATCH(1, (lookup_value1=lookup_range1) * (lookup_value2=lookup_range2), 0), return_column_number)

1. Använd formeln nedan i en tom cell där du vill placera resultatet och tryck sedan på Ctrl + Skift + Enter knappar tillsammans för att få det första matchade värdet, se skärmdump:

=INDEX($E$2:$G$9, MATCH(1, ($A2=$E$2:$E$9) * ($B2=$F$2:$F$9), 0), 3)

Anmärkningar: I ovanstående formel, vad cellreferenser representerar som nedan visas skärmdump:

2Välj sedan den första formelcellen och dra fyllningshandtaget för att kopiera den här formeln till andra celler efter behov:

tips: I Excel 2016 och senare versioner kan du också använda Power Query funktion för att slå samman två eller flera tabeller till en baserad på nyckelkolumner. Klicka för att veta detaljerna steg för steg.

9. Vlookup-matchande värden i flera kalkylblad

Har du någonsin försökt att Vlookup-värden i flera kalkylblad? Om jag antar att jag har följande tre kalkylblad med utbud av data, och nu vill jag få en del av motsvarande värden baserat på kriterierna från dessa tre kalkylblad för att få resultatet enligt nedanstående skärmdump. I det här fallet Vlookup-värden över flera kalkylblad tutorial kan göra dig en tjänst steg för steg.


VLOOKUP-matchade värden behåller cellformatering

1. Vlookup för att få cellformatering (cellfärg, teckensnittsfärg) tillsammans med uppslagsvärde

Som vi alla vet kan den normala Vlookup-funktionen bara hjälpa oss att returnera det matchade värdet från ett annat dataområde, men ibland kanske du vill returnera motsvarande värde tillsammans med cellformateringen, såsom fyllningsfärg, teckensnittsfärg, typsnitt som nedan visas skärmdump. Detta avsnitt kommer att prata om hur man får cellformatering med det returnerade värdet i Excel.

Gör med följande steg för att leta upp och returnera motsvarande värde tillsammans med cellformatering:

1. I kalkylbladet innehåller de data du vill Vlookup, högerklicka på arkfliken och välj Visa kod från snabbmenyn. Se skärmdump:

2. I det öppnade Microsoft Visual Basic för applikationer kopiera nedan VBA-kod till kodfönstret.

VBA-kod 1: Vlookup för att få cellformatering tillsammans med uppslagsvärde

Sub Worksheet_Change(ByVal Target As Range)
'Updateby Extendoffice
    Dim I As Long
    Dim xKeys As Long
    Dim xDicStr As String
    On Error Resume Next
    Application.ScreenUpdating = False
    xKeys = UBound(xDic.Keys)
    If xKeys >= 0 Then
        For I = 0 To UBound(xDic.Keys)
            xDicStr = xDic.Items(I)
            If xDicStr <> "" Then
                Range(xDic.Keys(I)).Interior.Color = _
                Range(xDic.Items(I)).Interior.Color
                Range(xDic.Keys(I)).Font.FontStyle = _
                Range(xDic.Items(I)).Font.FontStyle
                Range(xDic.Keys(I)).Font.Size = _
                Range(xDic.Items(I)).Font.Size
                Range(xDic.Keys(I)).Font.Color = _
                Range(xDic.Items(I)).Font.Color
                Range(xDic.Keys(I)).Font.Name = _
                Range(xDic.Items(I)).Font.Name
                Range(xDic.Keys(I)).Font.Underline = _
                Range(xDic.Items(I)).Font.Underline
            Else
                Range(xDic.Keys(I)).Interior.Color = xlNone
            End If
        Next
        Set xDic = Nothing
    End If
    Application.ScreenUpdating = True
End Sub

3. Fortfarande i Microsoft Visual Basic för applikationer fönstret klickar Insert > Modulernaoch kopiera sedan nedanstående VBA-kod 2 till modulfönstret.

VBA-kod 2: Vlookup för att få cellformatering tillsammans med uppslagsvärde

Public xDic As New Dictionary
Function LookupKeepFormat (ByRef FndValue, ByRef LookupRng As Range, ByRef xCol As Long)
    Dim xFindCell As Range
    On Error Resume Next
    Set xFindCell = LookupRng.Find(FndValue, , xlValues, xlWhole)
    If xFindCell Is Nothing Then
        LookupKeepFormat = ""
        xDic.Add Application.Caller.Address, ""
    Else
        LookupKeepFormat = xFindCell.Offset(0, xCol - 1).Value
        xDic.Add Application.Caller.Address, xFindCell.Offset(0, xCol - 1).Address
    End If
End Function

4. När du har infogat ovanstående koder klickar du sedan på verktyg > referenser i Microsoft Visual Basic för applikationer fönster. Kontrollera sedan Microsoft Script Runtime kryssrutan i rutan Referenser - VBAProject dialog ruta. Se skärmdumpar:

5. Klicka sedan OK för att stänga dialogrutan och sedan spara och stänga kodfönstret, gå nu tillbaka kalkylbladet och använd sedan denna formel: =LookupKeepFormat(E2,$A$1:$C$10,3) till en tom cell där du vill mata ut resultatet och tryck sedan på Enter. Se skärmdump:

Anmärkningar: I ovanstående formel, E2 är det värde du kommer att slå upp, A1: C10 är tabellområdet och antalet 3 är kolumnnumret i tabellen du vill att det matchade värdet ska returneras.

6. Välj sedan den första resultatcellen och dra ned fyllningshandtaget för att få alla resultat tillsammans med formateringen. Se skärmdump.


2. Behåll datumformatet från ett Vlookup-returvärde

Normalt, när du använder Vloook-funktionen för att slå upp och returnera det matchade datumformatvärdet, visas något nummerformat enligt nedanstående skärmdump. För att hålla datumformatet från ett returnerat resultat, bör du bifoga TEXT-funktionen till Vlookup-funktionen.

Använd nedanstående formel i en tom cell och dra sedan fyllningshandtaget för att kopiera denna formel till andra celler, och alla matchade datum har returnerats enligt nedanstående skärmdump:

=TEXT(VLOOKUP(E2,$A$2:$C$9,3,FALSE),"mm/dd/yyyy")

Anmärkningar: I ovanstående formel, E2 är utseendevärdet, A2: C9 är uppslagsområdet, numret 3 är kolumnnumret du vill att värdet ska returneras, mm / dd / åååå är det datumformat du vill behålla.


3. Vlookup och returnera matchande värde med cellkommentar

Har du någonsin försökt att Vlookup returnerar inte bara matchade celldata utan också cellkommentaren i Excel som följande skärmdump visas? För att lösa denna uppgift kan nedanstående användardefinierade funktion göra dig en tjänst.

1. Håll ner ALT + F11 nycklar för att öppna Microsoft Visual Basic för applikationer fönster.

2. Klicka Insert > Modulerna, kopiera och klistra sedan in följande kod i modulfönstret.

VBA-kod: Vlookup och returnera matchande värde med cellkommentar:

Function VlookupComment(LookVal As Variant, FTable As Range, FColumn As Long, FType As Long) As Variant
'Updateby Extendoffice
    Application.Volatile
    Dim xRet As Variant 'could be an error
    Dim xCell As Range
    xRet = Application.Match(LookVal, FTable.Columns(1), FType)
    If IsError(xRet) Then
        VlookupComment = "Not Found"
    Else
        Set xCell = FTable.Columns(FColumn).Cells(1)(xRet)
        VlookupComment = xCell.Value
        With Application.Caller
            If Not .Comment Is Nothing Then
                .Comment.Delete
            End If
            If Not xCell.Comment Is Nothing Then
                .AddComment xCell.Comment.Text
            End If
        End With
    End If
End Function

3. Spara och stäng sedan kodfönstret, ange den här formeln: =vlookupcomment(D2,$A$2:$B$9,2,FALSE) in i en tom cell för att hitta resultatet, och dra sedan fyllningshandtaget för att kopiera den här formeln till andra celler, nu returneras de matchade värdena och kommentarerna på en gång, se skärmdump:

Anmärkningar: I ovanstående formel, D2 är det uppslagsvärde du vill returnera motsvarande värde, A2: B9 är datatabellen du vill använda, numret 2 är kolumnnumret som innehåller det matchade värdet du vill returnera.


4. Hantera texten och de verkliga siffrorna i Vlookup

Till exempel har jag en rad data, ID-numret i den ursprungliga tabellen är nummerformat, i uppslagscellen som lagras som text, när du använder den normala Vlookup-funktionen visas ett felresultat # N / A som nedan visad. I det här fallet, hur kan du få rätt information om uppslagsnumret och originalnumret i tabellen har olika dataformat?

För att hantera texten och de verkliga siffrorna i Vlookup-funktionen, använd följande formel i en tom cell och dra sedan fyllningshandtaget ner för att kopiera den här formeln, och du får rätt resultat enligt nedanstående skärmdump:

=IFERROR(VLOOKUP(VALUE(D2),$A$2:$B$8,2,0),VLOOKUP(TEXT(D2,0),$A$2:$B$8,2,0))

Anmärkningar:

  • 1. I ovanstående formel, D2 är det uppslagsvärde du vill returnera motsvarande värde, A2: B8 är datatabellen du vill använda, numret 2 är kolumnnumret som innehåller det matchade värdet du vill returnera.
  • 2. Denna formel fungerar också bra om du inte är säker på var du har siffror och var du har text.

Ladda ner VLOOKUP-exempelfiler

Vlookup_basic_examples.xlsx

Advanced_Vlookup_examples.xlsx

Vlookup_keep_cell_formatting.zip



  • Super Formula Bar (enkelt redigera flera rader med text och formel); Läslayout (enkelt läsa och redigera ett stort antal celler); Klistra in i filtrerat intervall...
  • Sammanfoga celler / rader / kolumner och förvaring av data; Delat cellinnehåll; Kombinera duplicerade rader och summa / genomsnitt... Förhindra duplicerade celler; Jämför intervall...
  • Välj Duplicera eller Unikt Rader; Välj tomma rader (alla celler är tomma); Super Find och Fuzzy Find i många arbetsböcker; Slumpmässigt val ...
  • Exakt kopia Flera celler utan att ändra formelreferens; Skapa referenser automatiskt till flera ark; Sätt in kulor, Kryssrutor och mer ...
  • Favorit och sätt snabbt in formler, Intervall, diagram och bilder; Kryptera celler med lösenord; Skapa e-postlista och skicka e-post ...
  • Extrahera text, Lägg till text, ta bort efter position, Ta bort mellanslag; Skapa och skriva ut personsökningstalsatser; Konvertera mellan celler innehåll och kommentarer...
  • Superfilter (spara och tillämpa filterscheman på andra ark); Avancerad sortering efter månad / vecka / dag, frekvens och mer; Specialfilter av fet, kursiv ...
  • Kombinera arbetsböcker och arbetsblad; Sammanfoga tabeller baserat på nyckelkolumner; Dela data i flera ark; Batchkonvertera xls, xlsx och PDF...
  • Gruppering av pivottabell efter veckonummer, veckodagen och mer ... Visa olåsta, låsta celler av olika färger; Markera celler som har formel / namn...
kte-flik 201905
  • Aktivera flikredigering och läsning i Word, Excel, PowerPoint, Publisher, Access, Visio och Project.
  • Öppna och skapa flera dokument i nya flikar i samma fönster, snarare än i nya fönster.
  • Ökar din produktivitet med 50% och minskar hundratals musklick åt dig varje dag!
officetab botten
Say something here...
symbols left.
You are guest
or post as a guest, but your post won't be published automatically.
Loading comment... The comment will be refreshed after 00:00.

Be the first to comment.