Hoppa till huvudinnehåll

Räkna enkelt unika och distinkta värden – 7 exempel

Normalt i Excel är de unika värdena de värden som bara visas en gång i listan utan några dubbletter, och distinkta värden är alla olika värden (unika värden + 1:a dubblettförekomster). När du arbetar med en stor datamängd kan du behöva räkna antalet unika och distinkta värden bland dubbletter från en lista med celler enligt skärmbilden nedan. Denna handledning kommer att introducera några snabba knep för att räkna de unika och distinkta värdena i Excel.

Räkna unika värden i Excel

Räkna distinkta värden (unika och 1:a dubblettförekomster) i Excel


Ladda ner exempelfil

Räkna unika distinkta värden


Räkna unika värden i Excel

Det här avsnittet kommer att prata om några formelexempel för att räkna antalet unika värden, inklusive texter och siffror i en lista.

Räkna unika värden med formler

Antag att jag har en lista med namn som innehåller några dubbletter av namn i namnlistan. Nu behöver jag bara få antalet unika namn (som är fyllda med gul färg) enligt skärmbilden nedan:

För att lösa det här problemet kan följande matrisformel göra dig en tjänst:

Steg 1: Mata in formel

Skriv in eller kopiera formeln nedan till en tom cell där du vill mata ut resultatet:

=SUM(IF(COUNTIF(A2:A12,A2:A12)=1,1,0))
 Anmärkningar: I ovanstående formel, A2: A12 är datalistan som du vill räkna unik.

Steg 2: Tryck Ctrl + Skift + Enter nycklar för att få rätt resultat:

tips:

  1. Om din lista med celler innehåller några andra typer av data, såsom siffror, booleaner, felvärden, etc., när formeln ovan används, kommer den att få antalet unika värden oavsett datatyp.
  2. När datalistan innehåller tomma celler, kommer denna formel att utesluta de tomma cellerna.
  3. Till räkna endast de unika textvärdena om det finns andra typer av data, använd nedanstående matrisformel och tryck sedan på Ctrl + Skift + Enter nycklar för att returnera resultatet:
    =SUM(IF(ISTEXT(A2:A12)*COUNTIF(A2:A12,A2:A12)=1,1,0))
  4. Till räkna endast unika nummer från en lista över celler som innehåller alla typer av data, använd följande matrisformel och tryck sedan på Ctrl + Skift + Enter nycklar för att returnera resultatet:
    =SUM(IF(ISNUMBER(A2:A12)*COUNTIF(A2:A12,A2:A12)=1,1,0))

Räkna unika värden med några få klick av Kutools för Excel

Det kan vara smärtsamt för dig att komma ihåg formlerna när du behöver applicera dem nästa gång. Men om du har Kutools för Excel, med dess Räkna unika värden möjlighet till Formlerhjälpare, kan du få resultatet med bara några få klick. Se nedan demo:

  1. Klicka på en cell för att mata ut resultatet;
  2. Aktivera den här funktionen genom att klicka Kutools > Formel Helper > Formel Helper > Statistisk > Räkna unika värden;
  3. Välj datalistan > OK.
tips:
  1. För att tillämpa den här funktionen bör du ladda ner och installera det för det första.
  2. Smakämnen Formlerhjälpare funktionen samlar 40+ vanliga formler, som t.ex Extrahera unika värden, Extrahera celler med unika värden (inkludera de första dubbletterna), Räkna antalet värden separerade med komma, Summa baserat på samma text, och mer...

Räkna unika värden i Excel 365/2021 med formler

Om du använder Excel 365 eller Excel 2021 finns det en ny UNIK funktion som kan hjälpa dig att skapa enklare formler för att räkna unika värden i en uppsättning data.

Till exempel, för att räkna antalet unika namn i intervallet A2:A12, skriv in följande formel:

Steg 1: Kopiera eller ange formeln nedan

=IFERROR(ROWS(UNIQUE(A2:A12,,TRUE)), 0)
Anmärkningar: I denna formel, A2: A12 är datalistan som du vill ska räkna unika värden.

Steg 2: Tryck ange nyckel för att få resultatet:

tips:

  1. Om datalistan innehåller andra typer av data, såsom text, siffror, booleaner, felvärden, etc., kommer denna formel att få antalet unika värden oavsett datatyp.
  2. Ovanstående formel kommer att räkna unika värden inklusive tomma celler, om du vill utesluta de tomma, använd formeln nedan och behöver bara trycka på ange nyckel:
    =SUM(IF(COUNTIF(A2:A12,A2:A12)=1,1,0))

Räkna distinkta värden (unika och 1:a dubblettförekomster) i Excel

För att räkna de olika värdena (unika värden och 1:a dubblettförekomster) i en lista med celler, här kommer jag att introducera andra formler för att uppnå denna uppgift.

Räkna distinkta värden med formler

I Excel kan du använda någon av formlerna nedan för att returnera antalet distinkta värden.

Steg 1: Ange någon av formlerna nedan

Formel 1: Efter att ha matat in formeln, tryck ange nyckel.

=SUMPRODUCT(1/COUNTIF(A2:A12,A2:A12))      

Formel 2: Efter att ha matat in formeln, tryck Ctrl + Skift + Enter nycklar.

=SUM(1/COUNTIF(A2:A12,A2:A12))             
Anmärkningar: I dessa formler, A2: A12 är datalistan som du vill ska räkna olika värden.

Resultat:

tips:

  1. Om datalistan innehåller andra typer av data, såsom siffror, booleaner, felvärden, etc., kommer denna formel att få de distinkta värdena oavsett datatyp.
  2. När du använder formeln ovan får du #DIV/0 felvärde om datalistan innehåller tomma celler. För att fixa och ignorera tomma celler, bör du använda någon av följande formler:
    Formel 1: Efter att ha matat in formeln, tryck ange nyckel.
    =SUMPRODUCT((A2:A12<>"")/COUNTIF(A2:A12,A2:A12&""))        
    Formel 2: Efter att ha matat in formeln, tryck Ctrl + Skift + Enter nycklar.
    =SUM(IF(A2:A12<>"",1/COUNTIF(A2:A12, A2:A12), 0))       

  3. Till få endast antalet distinkta textvärden i en lista med data, använd nedanstående matrisformel och tryck Ctrl + Skift + Enter nycklar för att få resultatet:
    =SUM(IF(ISTEXT(A2:A12),1/COUNTIF(A2:A12, A2:A12),""))
  4. Till räkna endast distinkta numeriska värden, använd följande matrisformel och tryck på Ctrl + Skift + Enter nycklar för att få resultatet:
    =SUM(IF(ISNUMBER(A2:A12),1/COUNTIF(A2:A12, A2:A12),""))

Räkna distinkta värden med några få klick av Kutools för Excel

Om du behöver använda formlerna ofta i din arbetsbok kan det vara smärtsamt för dig att komma ihåg formlerna när du behöver tillämpa dem nästa gång. Men om du har Kutools för Excel, med dess Räkna celler med unika värden (inkludera den första duplikaten) möjlighet till Formlerhjälpare, kan du få resultatet med bara flera klick. Se nedan demo:

  1. Klicka på en cell för att mata ut resultatet;
  2. Aktivera den här funktionen genom att klicka Kutools > Formel Helper > Statistisk > Räkna unika celler med unika värden (inkludera den första dubbletten);
  3. Välj datalistan > OK.
tips:
  1. För att tillämpa den här funktionen bör du ladda ner och installera det för det första.
  2. Smakämnen Formlerhjälpare funktionen samlar 40+ vanliga formler, som t.ex Extrahera unika värden, Extrahera celler med unika värden (inkludera de första dubbletterna), Räkna antalet värden separerade med komma, Summa baserat på samma text, och mer...

Räkna distinkta värden med pivottabell

I Excel kan pivottabellen också hjälpa till att få antalet distinkta värden från en lista med data, vänligen gör med följande steg:

Steg 1: Skapa en pivottabell

  1. Välj datalistan och klicka sedan Insert > pivottabellen från bandet, se skärmdump:
  2. I poppade ut pivottabellen från tabell- eller intervalldialogrutan:
    (1). Välj ett nytt kalkylblad eller befintligt kalkylblad där du vill placera pivottabellen;
    (2). Kontrollera sedan Lägg till dessa data i datamodellen kryssrutan.
    (3). Klicka sedan OK knapp.

Steg 2: Ordna fältet och välj alternativet Distinkt antal

  1.  A Pivottabellfält rutan visas, dra namn fält till Värden område, se nedan demo:
  2. Klicka sedan på Antal namn rullgardinsmeny och välj Värde fältinställningar, se skärmdump:
  3. Och sedan, a Värde fältinställningar dialogrutan öppnas, välj Distinkt greve från listrutan under Sammanfatta värde efter fliken och klicka på OK knapp, se skärmdump:

Resultat:

Nu kommer den skapade pivottabellen att visa det distinkta antalet av datalistan som nedan skärmdump:

tips:

  1. Om du uppdaterar dina källdata, för att få den senaste räkningen, behöver du bara högerklicka på pivottabellen och välja refresh alternativ.
  2. Denna Distinkt greve alternativet är endast tillgängligt i Excel 2013 och senare.

Räkna distinkta värden i Excel 365/2021 med formler

I Excel 365 eller Excel 2021 kan du använda den nya UNIKA-funktionen med den normala COUNTA-funktionen för att skapa en enkel formel.

Kopiera eller skriv in formeln nedan i en tom cell och tryck ange nyckel för att få resultatet:

=COUNTA(UNIQUE(A2:A12)) 
Anmärkningar: I denna formel, A2: A12 är datalistan som du vill ska räkna distinkta värden.

tips:

  1. Om datalistan innehåller andra typer av data, såsom text, siffror, booleaner, felvärden, etc., kommer denna formel att räkna antalet distinkta värden oavsett datatyp.
  2. Ovanstående formel kommer att räkna distinkta värden inklusive tomma celler. Om du vill utesluta de tomma cellerna, använd formeln nedan och tryck på ange nyckel för att få resultatet:
    =COUNTA(UNIQUE(FILTER(A2:A12, A2:A12<>"")))    


Relaterade artiklar:

  • Räkna unika värden i pivottabellen
  • Som standard, när vi skapar en pivottabell baserad på en rad data som innehåller några dubbla värden, kommer alla poster också att räknas, men ibland vill vi bara räkna de unika värdena baserat på en kolumn för att få rätt skärmdumpresultat. I den här artikeln kommer jag att prata om hur man räknar de unika värdena i pivottabellen.
  • Räkna unika värden i en filtrerad kolumn
  • Om du har en lista med namn som fyllts med några dubbletter i en filtrerad kolumn och nu vill du bara räkna antalet unika namn från den här filtrerade listan. Har du några bra lösningar för att snabbt hantera detta jobb i Excel?
  • Räkna unika värden med flera kriterier
  • Här är en rad data som innehåller flera namn, projekt och platser, och vad som behöver göras är att ta reda på namnen som matchar de kriterier jag har listat och sedan räkna de matchade namnen en gång bara enligt nedanstående skärmdump. Har du några knep för att lösa detta jobb? I den här artikeln kommer jag att presentera trick.
  • Sammanfoga unika värden
  • Om jag har en lång lista med värden som innehåller några dubbletter av data, vill jag nu bara hitta de unika värdena och sedan sammanfoga dem till en enda cell. Hur kunde jag hantera detta problem snabbt och enkelt i Excel?
Comments (0)
No ratings yet. Be the first to rate!
There are no comments posted here yet
Please leave your comments in English
Posting as Guest
×
Rate this post:
0   Characters
Suggested Locations