Hur sparar jag Outlook-e-postmeddelanden automatiskt till hårddisk / disk?

Författare: Kelly Senast ändrad: 2025-04-16

För säkerhetskopiering, arbetsbevis eller andra ändamål kan du spara Outlook-e-postmeddelanden på hårddisken. Det är enkelt att spara flera e-postmeddelanden på disken genom att manuellt dra från Outlook till disk. Men vet du hur man automatiskt sparar varje inkommande e-post till disk? Denna artikel kommer att introducera en VBA för att hantera den i Outlook.

Spara Outlook-e-postmeddelanden automatiskt på hårddisken / disken

Spara Outlook-e-postmeddelanden automatiskt på hårddisken / disken

Denna metod introducerar en VBA för att automatiskt spara varje inkommande e-postmeddelande i Outlook som enskild HTML-fil till den specifika disken. Gör så här:

1. Tryck på tangenterna "Alt" + "F11" för att öppna fönstret Microsoft Visual Basic for Applications.

2. Expandera Project1 och dubbelklicka på "ThisOutlookSession" för att öppna det och klistra sedan in nedanstående VBA-kod i ThisOutlookSession-fönstret. Se skärmdump:

VBA: Spara Outlook-e-post automatiskt som HTML-filer på disken

Private WithEvents InboxItems As Outlook.Items
Sub Application_Startup()
    Dim xNameSpace As Outlook.NameSpace
    Set xNameSpace = Outlook.Application.Session
    Set InboxItems = xNameSpace.GetDefaultFolder(olFolderInbox).Items
End Sub

Private Sub InboxItems_ItemAdd(ByVal objItem As Object)
    Dim FSO
    Dim xMailItem As Outlook.MailItem
    Dim xFilePath As String
    Dim xRegEx
    Dim xFileName As String
    On Error Resume Next
    xFilePath = CreateObject("WScript.Shell").SpecialFolders(16)
    xFilePath = xFilePath & "\MyEmails"
    Set FSO = CreateObject("Scripting.FileSystemObject")
    If FSO.FolderExists(xFilePath) = False Then
        FSO.CreateFolder (xFilePath)
    End If
    Set xRegEx = CreateObject("vbscript.regexp")
    xRegEx.Global = True
    xRegEx.IgnoreCase = False
    xRegEx.Pattern = "\||\/|\<|\>|""|:|\*|\\|\?"
    If objItem.Class = olMail Then
        Set xMailItem = objItem
        xFileName = xRegEx.Replace(xMailItem.Subject, "")
        xMailItem.SaveAs xFilePath & "\" & xFileName & ".html", olHTML
    End If
    Exit Sub
End Sub

3. Spara VBA-koden och starta om Microsoft Outlook.

Från och med nu kommer varje inkommande e-postmeddelande att sparas som en individuell HTML-fil i mappen "MyEmails".

Anmärkningar:
(1) Denna VBA kommer att skapa en mapp med namnet "MyEmails" under dokumentmappen. Du kan ta reda på de automatiskt sparade e-postmeddelandena med denna mappsökväg: C:\Users\ditt_användarnamn\Documents\MyEmails
(2) Denna VBA kommer att fungera med e-postmeddelanden som tas emot i mappen Inkorg för standarde-postkontot.