Hur skriver jag ut uppgifter baserat på kategori i Outlook?

Antag att det finns olika färgkategorier i dina Outlook-uppgifter, och nu vill du skriva ut listor över uppgifter baserat på kategorierna på olika sidor. Hur kunde du lösa detta jobb i Outlook?

Skriv ut uppgifter baserat på kategorier på olika sidor manuellt en efter en

Skriv ut uppgifter baserat på kategorier på olika sidor med VBA-kod

Skriv ut uppgifter baserat på kategorier på olika sidor manuellt en efter en

I Outlook kan du skriva ut uppgifterna manuellt baserat på de olika kategorierna på olika sidor en efter en, gör så här:

1. Starta Outlook och gå till Aktivitetsfönstret och välj uppgiftsmappen du vill skriva ut och tryck sedan på Ctrl + E för att aktivera Sök rutan och sedan under Sök fliken, klicka kategoriseras och välj en färgkategori du behöver skriva ut, se skärmdump:

doc utskriftsuppgifter efter kategori 1

2. Och sedan listas alla uppgifter med den specifika färgkategorin på en gång, se skärmdump:

doc utskriftsuppgifter efter kategori 2

3. Fortsätt sedan med att klicka Fil > Skriva ut för att skriva ut denna uppgiftslista som följande skärmdump visas:

doc utskriftsuppgifter efter kategori 3

4. Upprepa stegen ovan för att skriva ut en lista över uppgifter med andra färgkategorier manuellt.

Skriv ut uppgifter baserat på kategorier på olika sidor med VBA-kod

Här är en VBA-kod som kan hjälpa dig att skriva ut uppgifterna baserat på kategorin på olika sidor samtidigt, gör med följande steg:

1. Gå till uppgift och välj den uppgiftsmapp som du vill skriva ut.

2. Håll sedan ner ALT + F11 nycklar för att öppna Microsoft Visual Basic för applikationer fönster.

3. Och klicka sedan på Insert > Modulerna, kopiera och klistra in koden nedan i den öppnade tomma modulen:

VBA-kod: Skriv ut uppgifter baserat på kategorier på olika sidor:

Sub PrintTaskList_SpecificColorCategory()
    Dim xTaskItems As Outlook.Items
    Dim xTask As Outlook.TaskItem
    Dim xDictionary As Scripting.Dictionary
    Dim xCategoryArr As Variant, xCategory As Variant
    Dim xExcelApp As Excel.Application
    Dim xExcelWorkbook As Excel.Workbook
    Dim xExcelWorksheet As Excel.Worksheet
    Dim xSheet As Excel.Worksheet
    Dim xKey As Variant
    Dim xKeyStr As String
    Dim i As Long, xLastRow As Integer
    On Error Resume Next
    If Application.ActiveExplorer.CurrentFolder.DefaultItemType <> olTaskItem Then Exit Sub
    Set xTaskItems = Application.ActiveExplorer.CurrentFolder.Items
    Set xDictionary = New Scripting.Dictionary
    For Each xTask In xTaskItems
        xCategoryArr = Split(xTask.Categories, ",")
        For Each xCategory In xCategoryArr
            If xDictionary.Exists(Trim(xCategory)) = False Then
               xDictionary.Add Trim(xCategory), 0
            End If
        Next
    Next
    If xDictionary.Count = 0 Then
        MsgBox "The current Task doesn’t have any category", vbOKOnly + vbInformation, "Kutools for Outlook"
        Exit Sub
    End If
    Set xExcelApp = New Excel.Application
    Set xExcelWorkbook = xExcelApp.Workbooks.Add
    xExcelApp.Visible = True
    i = 0
    If xDictionary.Count > xExcelWorkbook.Sheets.Count Then
        xExcelWorkbook.Sheets.Add Count:=xDictionary.Count - xExcelWorkbook.Sheets.Count
    End If
    For Each xKey In xDictionary.Keys
        xKeyStr = CStr(xKey)
        i = i + 1
        Set xExcelWorksheet = xExcelWorkbook.Sheets(i)
        xExcelWorksheet.Name = xKeyStr
        With xExcelWorksheet
             .Range("A1") = xKeyStr
             .Range("A1").Font.Bold = True
             .Range("A1").Font.Size = 18
             .Range("A1", "C1").HorizontalAlignment = xlCenter
             .Range("A1", "C1").VerticalAlignment = xlCenter
             .Range("A1", "C1").Merge
             .Range("A2") = "Subject"
             .Range("A2").Font.Bold = True
             .Range("B2") = "Start Date"
             .Range("B2").Font.Bold = True
             .Range("C2") = "Due Date"
             .Range("C2").Font.Bold = True
        End With
        For Each xTask In xTaskItems
            If InStr(xTask.Categories, xKeyStr) > 0 Then
               xLastRow = xExcelWorksheet.UsedRange.Rows.Count + 1
               With xExcelWorksheet
                    .Range("A" & xLastRow) = xTask.Subject
                    .Range("B" & xLastRow) = xTask.StartDate
                    .Range("C" & xLastRow) = xTask.DueDate
               End With
            End If
        Next
        xExcelWorksheet.Columns("A:C").AutoFit
    Next
    For Each xSheet In xExcelWorkbook.Sheets
        xSheet.PrintOut
    Next
    xExcelWorkbook.Close False
    xExcelApp.Quit
End Sub

4. Klicka sedan verktyg > Referensprojekt i Microsoft Visual Basic för applikationer fönster, i poppade ut Referenser-projekt1 dialogruta, kontrollera Microsoft Excel-objektbibliotek och Microsoft Scripting Runtime alternativ från Tillgängliga referenser listruta, se skärmdump:

doc utskriftsuppgifter efter kategori 4

5. Och klicka sedan på OK knappen, nu, tryck F5 nyckel för att köra den här koden, efter att koden är klar, kommer listorna över uppgifter med olika kategorier att skrivas ut på olika sidor.