Hur behåller jag kategorin när du svarar eller vidarebefordrar e-post i Outlook? 

Normalt när du svarar eller vidarebefordrar ett e-postmeddelande som jag har kategoriserat tas kategorin bort automatiskt i det skickade e-postmeddelandet. Om du vill behålla kategorin på utgående e-postmeddelanden när du svarar eller vidarebefordrar kommer den här artikeln att introducera en metod för att hantera den.

Behåll kategori när du svarar eller vidarebefordrar e-post med VBA-kod

---

Behåll kategori när du svarar eller vidarebefordrar e-post med VBA-kod

1. Håll ner ALT + F11 nycklar för att öppna Microsoft Visual Basic för applikationer fönster.

2. I Microsoft Visual Basic för applikationer dubbelklicka ThisOutlookSession från Project1 (VbaProject.OTM) rutan för att öppna läget och sedan kopiera och klistra in följande kod i den tomma modulen.

VBA-kod: Behåll kategori när du svarar eller vidarebefordrar e-post:

Private WithEvents GExplorer As Outlook.Explorer
Private WithEvents GInspectors As Outlook.Inspectors
Private WithEvents GMailItem As Outlook.MailItem
Private GCategories As String
Private Sub Application_Startup()
    Dim xApp As Outlook.Application
    Set xApp = Outlook.Application
    Set GExplorer = xApp.ActiveExplorer
    Set GInspectors = xApp.Inspectors
End Sub
Private Sub GExplorer_SelectionChange()
    On Error Resume Next
    If TypeName(GExplorer.Selection.Item(1)) <> "MailItem" Then Exit Sub
    Set GMailItem = GExplorer.Selection.Item(1)
    GCategories = GMailItem.Categories
End Sub
Private Sub GInspectors_NewInspector(ByVal Inspector As Inspector)
    On Error Resume Next
    If TypeName(Inspector.CurrentItem) <> "MailItem" Then Exit Sub
   Set GMailItem = Inspector.CurrentItem
    GCategories = GMailItem.Categories
End Sub
Private Sub GMailItem_Forward(ByVal Forward As Object, Cancel As Boolean)
    Call GetCategories(Forward)
End Sub
Private Sub GMailItem_Reply(ByVal Response As Object, Cancel As Boolean)
    Call GetCategories(Response)
End Sub
Private Sub GMailItem_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Call GetCategories(Response)
End Sub
Private Sub GetCategories(ByVal NewMail As Object)
    If NewMail.Class <> olMail Then Exit Sub
    NewMail.Categories = GCategories
End Sub

3. Spara och stäng sedan detta kodfönster, stäng och starta om Outlook, nu när du svarar eller vidarebefordrar ett e-postmeddelande med kategori kommer kategorin att sparas i det utgående meddelandet i Skickade föremål, se skärmdump: