Hur fyller jag automatiskt e-postämne med bilagans namn i Outlook?

För dem som är vana vid att använda bilagans namn som ämne för ett e-postmeddelande i Outlook, kommer det att ta tid att manuellt skriva in bilagans namn i ämnesraden varje gång. Som visas i gif-filen nedan, om du vill fylla e-postmeddelandets ämnesrad med bilagans namn automatiskt när du infogar en bilaga, kommer VBA-metoden i den här handledningen att hjälpa.

Fyll automatiskt e-postämnet med bilagans namn med VBA-kod

Kör följande VBA-kod för att automatiskt fylla i e-postämnet med namnet på den bifogade bilagan i Outlook.

1. Starta din Outlook, tryck på andra + F11 nycklar för att öppna Microsoft Visual Basic för applikationer fönster.

2. I Microsoft Visual Basic för applikationer dubbelklicka Projekt1 (VbProject.OTM) > Microsoft Outlook-objekt > ThisOutlookSession att öppna ThisOutlookSession (kod) redaktör.

3. Kopiera sedan följande VBA-kod till ThisOutlookSession (kod) redaktör.

VBA-kod: Fyll i e-postämnet automatiskt med bilagans namn

Public WithEvents GExplorer As Explorer
'Updated by Extendoffice 20220926
Public WithEvents GInspectors As Inspectors
Public WithEvents GMail As MailItem

Private Sub Application_Startup()
  Set GExplorer = Application.ActiveExplorer
  Set GInspectors = Application.Inspectors
End Sub

Private Sub GExplorer_InlineResponse(ByVal Item As Object)
  Set GMail = Item
End Sub

Private Sub GInspectors_NewInspector(ByVal Inspector As Inspector)
  Dim xItem As Object
  Set xItem = Inspector.CurrentItem
  If xItem.Class <> olMail Then Exit Sub
  Set GMail = xItem
End Sub

Private Sub GMail_AttachmentAdd(ByVal Att As Attachment)
  Dim xFileName As String
  On Error Resume Next
  If VBA.Trim(GMail.Subject) <> "" Then Exit Sub
  If MsgBox("Do you want to use the attachment name as the subject?", vbYesNo + vbInformation, "Kutools for Outlook") = vbNo Then Exit Sub
  xFileName = Att.DisplayName
  xFileName = Left$(xFileName, VBA.InStrRev(xFileName, ".") - 1)
  GMail.Subject = xFileName
End Sub

4. Nu måste du spara koden och starta om Outlook.

5. Från och med nu, när du infogar en bilaga i ett e-postmeddelande som inte har ett ämne ifyllt ännu, en Kutools for Outlook dialogrutan dyker upp och frågar dig om du vill använda bilagans namn som ämne, klicka på Ja knapp.

Då kommer ämnesraden att fyllas i med namnet på den bifogade bilagan automatiskt.

Anmärkningar: