Hoppa till huvudinnehåll

Räkna unika numeriska värden eller datum i en kolumn

Om du antar att du har en lista med nummer som innehåller några dubbletter, nu vill du räkna antalet unika värden eller värdena visas bara en gång i listan som visas nedan. I den här artikeln kommer vi att prata om några användbara formler för att lösa denna uppgift i Excel snabbt och enkelt.


Räkna unika numeriska värden eller datum i en kolumn i Excel 2019, 2016 och tidigare

Om du använder Excel 2019, 2016 och tidigare versioner kan du använda funktionerna SUMMA, FREKVENS, OM, COUNTIF, ISNUMBER för att få antalet unika värden eller de värden som bara förekommer en gång.

Räkna unika numeriska värden eller datum i en kolumn

För att räkna unika nummer från en lista kan funktionerna SUMMA och FREKVENS göra dig en tjänst, den generiska syntaxen är:

=SUM(--(FREQUENCY(range,range)>0))
  • range: Datakolumnen där du vill räkna unika värden från.

Skriv in eller kopiera följande formel till en tom cell för att mata ut resultatet och tryck sedan på ange nyckel för att få resultatet:

=SUM(--(FREQUENCY(A2:A12,A2:A12)>0))


Förklaring av formeln:

=SUM(--(FREQUENCY(A2:A12,A2:A12)>0))

  • FREKVENS(A2:A12;A2:A12): FREKVENS-funktionen returnerar antalet för varje numeriskt värde i listan A2:A12, och den kommer att få en matris så här: {1;2;0;2;0;1;1;3;0;0;1; 0}. Siffrorna i arrayen anger hur många gånger värdena visas i kolumnen. Och siffran 0s i arrayen betyder att siffrorna redan har visats i dataområdet.
  • --(FREQUENCY(A2:A12,A2:A12)>0=--({1;2;0;2;0;1;1;3;0;0;1;0})>0: Varje värde i matrisen kommer att jämföras med noll: om det är större än 0 visas ett TRUE, annars visas ett FALSE. Och sedan konverterar det dubbla negativa tecknet TRUEs och FALSEs till 1s och 0s, så det kommer att returnera resultatet så här: {1;1;0;1;0;1;1;1;0;0;1;0; XNUMX}.
  • SUM(--(FREQUENCY(A2:A12,A2:A12)>0))=SUM({1;1;0;1;0;1;1;1;0;0;1;0}): Äntligen summerar SUM-funktionen alla värden i arrayen och får resultatet: 7.

Räkna unika numeriska värden eller datum som bara visas en gång i en kolumn

Räkna de unika numeriska värdena som endast visas en gång från en lista, du bör kombinera funktionerna SUM, OM, ISNUMBER och COUNTIF för att skapa formeln, den generiska syntaxen är:

{=SUM(IF(ISNUMBER(range)*COUNTIF(range,range)=1,1,0))}
Array formula, should press Ctrl + Shift + Enter keys together.
  • range: Datakolumnen där du vill räkna unika värden från.

Skriv in eller kopiera formeln nedan till en tom cell och tryck sedan på Ctrl + Skift + Enter tangenter samtidigt för att få rätt resultat:

=SUM(IF(ISNUMBER(A2:A12)*COUNTIF(A2:A12,A2:A12)=1,1,0))


Förklaring av formeln:

=SUM(IF(ISNUMBER(A2:A12)*COUNTIF(A2:A12,A2:A12)=1,1,0))

  • ISNUMMER(A2:A12): Denna ISNUMBER-funktion används för att kontrollera värdena i listan A2:A12 om de är siffror eller inte. Den returnerar TRUE om en cell innehåller ett numeriskt värde, och FALSE om inte. Så du kommer att få en array så här: {TRUE;TRUE;TRUE;TRUE;TRUE;TRUE;TRUE;TRUE;TRUE;TRUE;TRUE}.
  • ANTAL.OM(A2:A12;A2:A12): COUNTIF-funktionen räknar hur många gånger varje värde förekommer i det specifika intervallet, den returnerar resultatet så här: {1;2;2;2;2;1;1;3;3;3;1}.
  • ISNUMBER(A2:A12)*COUNTIF(A2:A12,A2:A12)= {TRUE;TRUE;TRUE;TRUE;TRUE;TRUE;TRUE;TRUE;TRUE;TRUE;TRUE}* {1;2;2;2;2;1;1;3;3;3;1}: Dessa två uttryck multipliceras för att få detta resultat: {1;2;2;2;2;1;1;3;3;3;1}.
  • IF(ISNUMBER(A2:A12)*COUNTIF(A2:A12,A2:A12)=1,1,0)=IF({1;2;2;2;2;1;1;3;3;3;1}=1,1,0): Här kontrollerar IF-funktionen varje värde i arrayen om de är lika med 1 eller inte: Om ja, kommer ett nummer 1 att returneras; om inte, visas ett nummer 0. Resultatet är så här: {1;0;0;0;0;1;1;0;0;0;1}.
  • SUM(IF(ISNUMBER(A2:A12)*COUNTIF(A2:A12,A2:A12)=1,1,0))=SUM({1;0;0;0;0;1;1;0;0;0;1}): Slutligen lägger SUM-funktionen ihop värdena i arrayen och returnerar det totala antalet unika värden: 4.

Räkna unika numeriska värden eller datum i en kolumn i Excel 365

I Excel 365 finns en ny enkel funktion som heter UNIQUE. Att ha denna funktion innesluten i COUNT-funktionen kan hjälpa dig att hantera denna uppgift snabbt som du behöver.

Räkna unika numeriska värden eller datum i en kolumn

Den generiska syntaxen för att räkna de unika numeriska värdena eller datumen i Excel 365 är:

=COUNT(UNIQUE(range))
  • range: Datakolumnen där du vill räkna unika värden från.

Ange eller kopiera formeln nedan till en tom cell och tryck ange nyckel för att få resultatet, se skärmdump:

=COUNT(UNIQUE(A2:A12))


Förklaring av formeln:

=COUNT(UNIQUE(A2:A12))

  • UNIK(A2:A12): Den här UNIK-funktionen extraherar alla unika värden från listan, och du får en arraylista så här: {258;560;774;801;985;990;1569}.
  • COUNT(UNIQUE(A2:A12))=COUNT({258;560;774;801;985;990;1569}): Denna COUNT-funktion räknar antalet numeriska värden och returnerar resultatet: 7.

Räkna unika numeriska värden eller datum som bara visas en gång i en kolumn

Denna UNIKA funktion kan också extrahera de unika värdena som förekommer exakt en gång från en lista, den generiska syntaxen är:

=COUNT(UNIQUE(range,0,1))
  • range: Datakolumnen där du vill räkna unika värden från.

Skriv in eller kopiera följande formel till en cell där du vill returnera resultatet och tryck sedan på ange nyckel, se skärmdump:

=COUNT(UNIQUE(A2:A12,0,1))


Förklaring av formeln:

=COUNT(UNIQUE(A2:A12,0,1))

  • UNIK(A2:A12,0,1): Den här UNIK-funktionen extraherar de unika värdena som endast visas en gång från listan, och du kommer att få en arraylista så här: {258;801;985;1569}.
  • COUNT(UNIQUE(A2:A12,0,1))=COUNT({258;801;985;1569}): Denna COUNT-funktion räknar antalet numeriska värden och returnerar resultatet: 4.

tips: Alla ovanstående formler är tillgängliga för att räkna de unika datumen i en kolumn.


Relativ funktion som används:

  • BELOPP:
  • Excel SUMM -funktionen returnerar summan av angivna värden.
  • FREKVENS:
  • FREKVENS -funktionen beräknar hur ofta värden förekommer inom ett intervall av värden och returnerar sedan ett vertikalt antal siffror.
  • ISNUMBER:
  • Excel ISNUMBER -funktionen returnerar TRUE när en cell innehåller ett tal och FALSE om inte.
  • RÄKNING:
  • COUNTIF-funktionen är en statistisk funktion i Excel som används för att räkna antalet celler som uppfyller ett kriterium.
  • RÄKNA:
  • Räkningsfunktionen används för att räkna antalet celler som innehåller siffror eller räkna siffrorna i en lista med argument.
  • UNIK:
  • Funktionen UNIK returnerar en lista med unika värden i en lista eller intervall.

Fler artiklar:

  • Räkna unika numeriska värden baserade på kriterier
  • I Excel -kalkylblad kan du drabbas av ett problem som räknar antalet unika numeriska värden baserat på ett specifikt villkor. Till exempel, hur kan jag räkna de unika Qty-värdena för produkten ”T-shirt” från rapporten enligt nedanstående skärmdump? I den här artikeln kommer jag att visa några formler för att uppnå denna uppgift i Excel.
  • Räkna antalet celler är lika med ett av många värden
  • Om jag antar att jag har en lista över produkter i kolumn A, nu vill jag få det totala antalet specifika produkter Apple, Grape and Lemon som anges i intervall C4: C6 från kolumn A enligt nedanstående skärmdump. Normalt fungerar inte Excel i de här funktionerna i enkla COUNTIF- och COUNTIFS -funktioner. Denna artikel, jag kommer att prata om hur man löser detta jobb snabbt och enkelt med kombinationen av SUMPRODUCT och COUNTIF -funktioner.
  • Räkna antal celler som innehåller specifikt antal tecken
  • Om du vill räkna antalet celler som innehåller ett visst antal tecken (t.ex. 5 tecken) i ett cellintervall enligt nedanstående skärmdump. I Excel kan funktionen COUNTIF göra dig en tjänst. I denna artikel kommer jag att prata om hur man får antal celler som innehåller exakt x tecken eller celler som innehåller mer än ett visst antal tecken.

De bästa Office-produktivitetsverktygen

Kutools för Excel - Hjälper dig att sticka ut från mängden

Populära funktioner: Hitta, markera eller identifiera dubbletter  |  Ta bort tomma rader  |  Kombinera kolumner eller celler utan att förlora data  |  Rund utan formel ...
Super VLookup: Flera kriterier  |  Multipelt värde  |  Över flera ark  |  Fuzzy Lookup...
Adv. Rullgardinslista: Enkel rullgardinslista  |  Beroende rullgardinslista  |  Flervals-rullgardinslista...
Kolumnhanterare: Lägg till ett specifikt antal kolumner  |  Flytta kolumner  |  Växla synlighetsstatus för dolda kolumner  Jämför kolumner med Välj Samma och olika celler ...
Utvalda funktioner: Rutnätsfokus  |  Designvy  |  Stor formelbar  |  Arbetsbok & Bladhanterare | Resursbibliotek (Automatisk text)  |  Datumväljare  |  Kombinera arbetsblad  |  Kryptera/Dekryptera celler  |  Skicka e-postmeddelanden efter lista  |  Superfilter  |  Specialfilter (filtrera fet/kursiv/genomstruken...) ...
Topp 15 verktygssatser12 text verktyg (lägga till text, Ta bort tecken ...)  |  50 + Diagram Typer (Gantt Chart ...)  |  40+ Praktiskt Formler (Beräkna ålder baserat på födelsedag ...)  |  19 Införande verktyg (Infoga QR-kod, Infoga bild från sökväg ...)  |  12 Konvertering verktyg (Siffror till ord, Valutaväxling ...)  |  7 Slå ihop och dela verktyg (Avancerade kombinera rader, Dela upp Excel-celler ...)  |  ... och mer

Kutools för Excel har över 300 funktioner, Se till att det du behöver bara är ett klick bort...


Fliken Office - Aktivera läsning och redigering av flikar i Microsoft Office (inkluderar Excel)

  • En sekund att växla mellan dussintals öppna dokument!
  • Minska hundratals musklick åt dig varje dag, säg adjö till mushanden.
  • Ökar din produktivitet med 50 % när du visar och redigerar flera dokument.
  • Ger effektiva flikar till Office (inklusive Excel), precis som Chrome, Edge och Firefox.
Comments (0)
No ratings yet. Be the first to rate!
There are no comments posted here yet
Please leave your comments in English
Posting as Guest
×
Rate this post:
0   Characters
Suggested Locations