Dela upp måtten i individuell längd, höjd och bredd
Den här artikeln förklarar hur man delar upp dimensioner i en cell i tre delar (individuella mått som inkluderar längd, höjd och bredd).
Hur delar man upp dimensioner i tre delar?
För att dela upp dimensioner i individuell längd, höjd och bredd måste du använda tre olika formler separat.
Generisk formel för att extrahera den första dimensionen
=LEFT(text,FIND("char",text)-1)
Generisk formel för att extrahera den andra dimensionen
=MID(text,FIND("char",text)+1,FIND("@",SUBSTITUTE(text,"char","@",2))-(FIND("char",text)+1))
Generisk formel för att extrahera den tredje dimensionen
=RIGHT(text,LEN(text)-FIND("@",SUBSTITUTE(text,"char","@",2)))
Argument med ovanstående formler
Text: Strängen du vill extrahera det angivna antalet tecken från den. Det kan vara:
- 1. Texten i citattecken;
- 2. Eller en hänvisning till en cell som innehåller texten.
Röding: Karaktären du delar upp dimensionerna baserat på.
Hur använder jag dessa formler?
För det första måste vi få den första dimensionen.
1. Välj en tom cell för att mata ut den första dimensionen.
2. Ange formeln nedan och tryck på ange nyckel. Välj resultatcellen och dra Fill Handle för att tillämpa formeln på andra celler efter behov.
=LEFT(B5,FIND("x",B5)-1)
Sedan ska vi dela upp den andra dimensionen enligt följande.
1. Välj en tom cell för att mata ut den andra dimensionen.
2. Ange formeln nedan och tryck på ange nyckel. Välj resultatcellen och dra Fill Handle för att tillämpa formeln på andra celler efter behov.
=MID(B5,FIND("x",B5)+1,FIND("@",SUBSTITUTE(B5,"x","@",2))-(FIND("x",B5)+1))
Slutligen, få den sista dimensionen
1. Välj en tom cell för att mata ut den sista dimensionen.
2. Ange formeln nedan och tryck på ange nyckel. Välj resultatcellen och dra Fill Handle för att tillämpa formeln på andra celler efter behov.
=RIGHT(B5,LEN(B5)-FIND("@",SUBSTITUTE(B5,"x","@",2)))
Hur fungerar dessa formler?
=LEFT(B5,FIND("x",B5)-1)
1. FIND("x",B5)-1: HITTA-funktionen får positionen för det första "x" i B5. För att få den första dimensionen utan den första "x" måste du subtrahera 1. Då är resultatet 4-1 = 3.
2. LEFT(B5,3): VÄNSTER-funktionen extraherar 3 tecken som börjar från vänster sida av B5 och returnerar resultatet som 100.
=MID(B5,FIND("x",B5)+1,FIND("@",SUBSTITUTE(B5,"x","@",2))-(FIND("x",B5)+1))
1. FIND("x",B5)+1: HITTA-funktionen lokaliserar den första "x" av B5. Eftersom du behöver få den andra dimensionen efter det första "x", här krävs att lägga till 1. Då är resultatet 4 + 1 = 5.
2. FIND("@",SUBSTITUTE(B5,"x","@",2)):
- SUBSTITUTE(B5,"x","@",2): SUBSTITUTE-funktionen ersätter den andra "x" i B5 med "@" och returnerar resultatet som 100x50 @ 300;
- FIND("@",100x50@300): HITTA-funktionen här får positionen för "@" -tecknet i texten 100x50 @ 300 och returnerar resultatet som 7.
3. (FIND("x",B5)+1): Som ovan nämnts i steg 1, hittar FIND-funktionen här den första "x" av B5 och lägger till 1 för att returnera resultatet som 5.
4. MID(B5,5,7-(5)): MID-funktionen extraherar två tecken (7-5 = 2) med början vid det femte tecknet i texten i B5. Och ge slutresultatet 50.
=RIGHT(B5,LEN(B5)-FIND("@",SUBSTITUTE(B5,"x","@",2)))
1. LEN(B5): LEN-funktionen beräknar den totala stränglängden i B5 och returnerar resultatet som 10;
2. FIND("@",SUBSTITUTE(B5,"x","@",2)):
- SUBSTITUTE(B5,"x","@",2): SUBSTITUTE-funktionen ersätter den andra "x" i B5 med "@" och returnerar resultatet som 100x50 @ 300;
- FIND("@",100x50@300): HITTA-funktionen lokaliserar "@" i texten 100x50 @ 300 och returnerar resultatet som 7.
3. LEN(B5)-FIND("@",SUBSTITUTE(B5,"x","@",2)): (10-7) Den totala längden på textsträngen i cell B5 subtraherar de första 7 tecknen och returnerar resultatet som 3.
4. RIGHT(B5,3): Och sedan extraherar HÖGER-funktionen tre tecken som börjar från höger sida av B3 och returnerar den tredje dimensionen som 5.
Relaterade funktioner
Excel VÄNSTER-funktion
VÄNSTER-funktionen extraherar det angivna antalet tecken från vänster sida av en medföljande sträng.
Excel MID-funktion
MID-funktionen används för att hitta och returnera ett visst antal tecken från mitten av den angivna textsträngen.
Excel RIGHT-funktion
RIGHT-funktionen extraherar ett visst antal tecken från textsträngens högra sida.
Excel HITTA-funktion
HITTA-funktionen används för att hitta en sträng inom en annan sträng och returnerar startpositionen för strängen inuti en annan sträng.
Excel LEN-funktion
LEN-funktionen returnerar antalet tecken i en textsträng.
Excel SUBSTITUTE-funktion
Microsoft Excel SUBSTITUTE-funktion ersätter text eller tecken i en textsträng med en annan text eller andra tecken.
Relaterade formler
Dela dimensioner i två delar i Excel
Den här artikeln förklarar hur man använder formel för att dela upp dimensioner i en cell i två delar utan enheter (individuell längd och bredd).
Separera nummer från måttenheter
Den här artikeln förklarar hur man använder formel för att separera siffror från måttenheter.
De bästa Office-produktivitetsverktygen
Kutools för Excel - Hjälper dig att sticka ut från mängden
Kutools för Excel har över 300 funktioner, Se till att det du behöver bara är ett klick bort...
Fliken Office - Aktivera läsning och redigering av flikar i Microsoft Office (inkluderar Excel)
- En sekund att växla mellan dussintals öppna dokument!
- Minska hundratals musklick åt dig varje dag, säg adjö till mushanden.
- Ökar din produktivitet med 50 % när du visar och redigerar flera dokument.
- Ger effektiva flikar till Office (inklusive Excel), precis som Chrome, Edge och Firefox.
