Summa om celler innehåller specifik text i en annan kolumn
Den här handledningen visar hur du summerar värden om celler innehåller specifik eller deltext i en annan kolumn. Ta dataintervallet nedan som ett exempel, för att få de totala mängderna av produkterna som innehåller texten "T-shirt", både SUMIF-funktionen och SUMPRODUKT-funktionen kan hantera denna uppgift i Excel.
- Summa värden om cellen innehåller specifik eller deltext med SUMIF-funktionen
- Summa värden om cellen innehåller specifik eller deltext med SUMMAPRODUKT-funktionen
Summa värden om cellen innehåller specifik eller deltext med SUMIF-funktionen
För att summera värden om en cell innehåller specifik text i en annan kolumn kan du använda SUMIF-funktionen med ett jokertecken (*), de generiska syntaxerna är:
Generisk formel med hårdkodad text:
=SUMIF(range,"*text*",sum_range)
- range: Dataintervallet du vill utvärdera med hjälp av kriterierna;
- *text*: Kriterierna du vill summera värden utifrån. Här används jokertecknet * för att hitta valfritt antal tecken, för att matcha alla objekt som innehåller en specifik text, placera texten mellan de två *-tecknen. (Observera att du måste omge texten och jokertecken med dubbla citattecken.)
- sum_range: Området av celler med matchade numeriska värden som du vill summera.
Generisk formel med cellreferens:
=SUMIF(range,"*"&cell&"*",sum_range)
- range: Dataintervallet du vill utvärdera med hjälp av kriterierna;
- "*"&cell&"*": Kriterierna du vill summera värden baserat på;
- *: Jokertecken som hittar valfritt antal tecken.
- cellen: Cellen innehåller den specifika texten att leta efter.
- &: Denna sammanlänkningsoperator (&) används för att sammanfoga en cellreferens med asteriskerna.
- sum_range: Området av celler med matchade numeriska värden som du vill summera.
Efter att ha känt till funktionens grundläggande funktion, använd någon av följande formler du behöver och tryck sedan på ange nyckel för att få resultatet:
=SUMIF($A$2:$A$12,"*T-shirt*",$B$2:$B$12) (Type the criteria manually)
=SUMIF($A$2:$A$12,"*"&D2&"*",$B$2:$B$12) (Use a cell reference)
=SUMIF($A$2:$A$12,"*"&D2&"*",$B$2:$B$12) (Use a cell reference)
Anmärkningar: Denna SUMIF-funktion är inte skiftlägeskänslig.
Summa värden om cellen innehåller specifik eller deltext med SUMMAPRODUKT-funktionen
SUMPRODUCT-funktionen kan också hjälpa dig att avsluta det här jobbet utan att använda något jokertecken. Här bör du linda funktionerna ISNUMBER och SEARCH i en SUMPRODUCT-funktion, den generiska syntaxen är:
=SUMPRODUCT(sum_range *(ISNUMBER(SEARCH(criteria,range))))
- sum_range: Området av celler med matchade numeriska värden som du vill summera;
- criteria: Kriterierna du vill summera värden utifrån. Det kan vara en cellreferens eller specifik text du definierat;
- range: Dataintervallet du vill utvärdera med hjälp av kriterierna;
Använd någon av formlerna nedan i en tom cell och tryck ange nyckel för att returnera resultatet:
=SUMPRODUCT($B$2:$B$12*(ISNUMBER(SEARCH("T-Shirt",$A$2:$A$12)))) (Type the criteria manually)
=SUMPRODUCT($B$2:$B$12*(ISNUMBER(SEARCH(D2,$A$2:$A$12)))) (Use a cell reference)
=SUMPRODUCT($B$2:$B$12*(ISNUMBER(SEARCH(D2,$A$2:$A$12)))) (Use a cell reference)
Förklaring av denna formel:
=SUMMAPRODUKT($B$2:$B$12*(ISNUMBER(SÖK("T-Shirt",$A$2:$A$12))))
- SEARCH("T-shirt",$A$2:$A$12): SEARCH-funktionen returnerar platsen för den specifika texten "T-Shirt" från dataområdet A2:A12, så du får en array så här: {5;#VALUE!;#VALUE!;7;#VALUE! ;7;#VÄRDE!;#VÄRDE!;#VÄRDE!;#VÄRDE!;7}.
- ISNUMBER(SEARCH("T-Shirt",$A$2:$A$12))= ISNUMBER({5;#VALUE!;#VALUE!;7;#VALUE!;7;#VALUE!;#VALUE!;#VALUE!;#VALUE!;7}): Denna ISNUMBER-funktion används för att testa för de numeriska värdena och returnerar en ny array: {TRUE;FALSE;FALSE;TRUE;FALSE;TRUE;FALSE;FALSE;FALSE;FALSE;TRUE}.
- $B$2:$B$12*(ISNUMBER(SEARCH("T-Shirt",$A$2:$A$12)))= {347;428;398;430;228;379;412;461;316;420;449}*{TRUE;FALSE;FALSE;TRUE;FALSE;TRUE;FALSE;FALSE;FALSE;FALSE;TRUE}: För att multiplicera dessa två arrayer tvingar matematisk operation värdena TRUE och FALSE till 1:or och 0:or. Så multiplikationen av de två matriserna blir så här: {347;428;398;430;228;379;412;461;316;420;449}*{1;0;0;1;0;1; 0;0;0;0;1}={347;0;0;430;0;379;0;0;0;0;449}.
- SUMPRODUCT($B$2:$B$12*(ISNUMBER(SEARCH("T-Shirt",$A$2:$A$12)))) =SUMPRODUCT({347;0;0;430;0;379;0;0;0;0;449}):Slutligen summerar SUMPRODUCT-funktionen alla värden i arrayen för att få resultatet:1605.
Relativ funktion som används:
- SUMIF:
- SUMIF-funktionen kan hjälpa till att summera celler baserat på ett kriterium.
- SUMPRODUCT:
- SUMPRODUCT-funktionen kan användas för att multiplicera två eller flera kolumner eller matriser tillsammans och sedan få summan av produkter.
- ISNUMBER:
- Excel ISNUMBER -funktionen returnerar TRUE när en cell innehåller ett tal och FALSE om inte.
- SÖK:
- SEARCH-funktionen kan hjälpa dig att hitta positionen för ett visst tecken eller en delsträng från den givna textsträngen
Fler artiklar:
- Summa om börjar med eller slutar med specifik text eller tecken
- För att summera värden om motsvarande celler börjar med eller slutar med ett specifikt värde, kan du använda SUMIF-funktionen med ett jokertecken (*) för att ta bort det. Den här artikeln kommer att presentera hur man använder formeln i detalj.
- Summa minsta eller nedersta N -värden
- I Excel är det lätt för oss att summera ett cellintervall genom att använda SUM-funktionen. Ibland kan du behöva summera de minsta eller lägsta 3, 5 eller n siffrorna i ett dataintervall enligt skärmbilden nedan. I det här fallet kan SUMPRODUKTEN tillsammans med SMALL-funktionen hjälpa dig att lösa detta problem i Excel.
- Summa minsta eller nedersta N -värden baserat på kriterier
- I tidigare handledning har vi diskuterat hur man summerar de minsta n värdena i ett dataintervall. I den här artikeln kommer vi att utföra ytterligare en avancerad operation – att summera de lägsta n värdena baserat på ett eller flera kriterier i Excel.
De bästa Office-produktivitetsverktygen
Kutools för Excel - Hjälper dig att sticka ut från mängden
Kutools för Excel har över 300 funktioner, Se till att det du behöver bara är ett klick bort...
Fliken Office - Aktivera läsning och redigering av flikar i Microsoft Office (inkluderar Excel)
- En sekund att växla mellan dussintals öppna dokument!
- Minska hundratals musklick åt dig varje dag, säg adjö till mushanden.
- Ökar din produktivitet med 50 % när du visar och redigerar flera dokument.
- Ger effektiva flikar till Office (inklusive Excel), precis som Chrome, Edge och Firefox.
