excel CHOOSE fungera

Beskrivning

Syntax och argument

Användning och exempel

• Ex1 - Grundläggande användning: använder CHOOSE funktion ensam för att välja värde från listargument
• Ex2 - Returnera olika resultat baserat på flera villkor
• Ex3 - Returnera olika beräknade resultat baserat på förhållanden
• Ex4 - Välj slumpmässigt från listan
• Ex5 - Kombinera CHOOSE och VLOOKUP funktioner för att returnera värde i vänster kolumn
• Ex6 - Retur vardag eller månad baserat på angivet datum
• Ex7 - Återgå till nästa arbetsdag / helgdatum baserat på idag

---

Beskrivning

Smakämnen CHOOSE funktionen returnerar ett värde från listan över värdeargument baserat på det angivna indexnumret. Till exempel, CHOOSE(3,”Apple”,”Peach”,”Orange”) returnerar Orange, indexnumret är 3 och Orange är det tredje värdet efter indexnumret i funktionen.

syntax och argument

Formelsyntax

CHOOSE(index_num, value1, [value2], …)

Argument

Index_num: Nödvändig. Ett numeriskt värde mellan 1-254 och indirekt vilket argumentvärde som ska väljas. om index_num är utanför skalan mellan 1-254, CHOOSE returnerar #VALUE! felvärde. Om index_num är ett decimalvärde avrundas det till ett heltal innan formeln används. Value1: Nödvändig. Det första värdet i formeln som kan väljas. Value2: Frivillig. Det andra och upp till 254: e värdet att välja mellan.

Value1, value2... kan vara siffror, texter, formler, cellreferenser eller definierat namn.

Returvärde

Smakämnen CHOOSE funktionen returnerar ett värde från en lista baserat på den angivna positionen.

Användning och exempel

I den här delen listar jag några enkla men representativa exempel för att förklara användningen av CHOOSE funktion.

Ex1 - Grundläggande användning: använder CHOOSE funktion ensam för att välja värde från listargument

Formel 1:

=CHOOSE(3,"a","b","c","d")

Return: c, vilket är det tredje argumentet efter index_numret på 3 i CHOOSE funktion.

Obs! Använd dubbla citat som omger värdet om det är text.

Formel 2:

=CHOOSE(2,A1,A2,A3,A4)

Retur: Kate, värdet på A2. Eftersom index_num är 2 och A2 är det andra värdet i CHOOSE funktion.

Formel 3:

=CHOOSE(4,8,9,7,6)

Return: 6, det fjärde listargumentet i funktionen.

---

Ex2 - Returnera olika resultat baserat på flera villkor

Antag att du har en lista med avvikelser för varje produkt som behövde märkas baserat på förhållandena som visas nedan.

Vanligtvis kan du använda IF-funktionen för att hantera, men här introducerar jag hur du använder CHOOSE funktion för att enkelt lösa detta problem

Formel:

=CHOOSE((B7>0)+(B7>1)+(B7>5),"Top","Middle","Bottom")

Förklara:

(B7>0)+(B7>1)+(B7>5): index_num, B7 är 2, vilket är större än 0 och 1 men mindre än 5, så vi får mellanresultatet:

=CHOOSE(True+Ture+False,"Top","Middle","Bottom")

Som vi vet är True = 1, False = 0, så formeln kan ses som:

=CHOOSE(1+1+0,"Top","Middle","Bottom")

sedan

=CHOOSE(2,"Top","Middle","Bottom")

Resultat: mitten

---

Ex3 - Returnera olika beräknade resultat baserat på förhållanden

Om du antar att du måste beräkna rabatterna för varje produkt baserat på belopp och pris enligt nedanstående skärmdump:

Formel:

=CHOOSE((B8>0)+(B8>100)+(B8>200)+(B8>300),B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5)

Förklara:

(B8>0)+(B8>100)+(B8>200)+(B8>300): index_nummer, B8 är 102, vilket är större än 100 men mindre än 201, så i denna del returnerar det resultatet som visas:

=CHOOSE(true+true+false+false,B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5)

=CHOOSE(1+1+0+0,B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5)

sedan

=CHOOSE(2,B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5)

B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5: värdena att välja från, rabatt är lika med pris * belopp * rabattprocent, eftersom här index_num är 2, väljer det B8 * C8 * 0.2

Returnerar: 102 * 2 * 0.2 = 40.8

---

Ex4 - Välj slumpmässigt från listan

Ibland kan du ibland behöva slumpmässigt välja ett värde från en viss lista, CHOOSE funktionen kan lösa detta jobb.

Slumpmässigt välja ett värde från en lista:

Formel:

=CHOOSE(RANDBETWEEN(1,5),$D$2,$D$3,$D$4,$D$5,$D$6)

Förklara:

RANDBETWEEN(1,5): index_num, få slumpmässigt nummer mellan 1 och 5

$D$2,$D$3,$D$4,$D$5,$D$6: listan över värden att välja mellan

---

Ex5 - Kombinera CHOOSE och VLOOKUP funktioner för att returnera värde i vänster kolumn

Generellt använder vi VLOOKUP-funktionen =VLOOKUP (value, table, col_index, [range_lookup]) för att returnera ett värde baserat på ett givet värde från ett tabellintervall. Men med VLOOKUP funktion, kommer det att returnera ett felvärde medan returkolumnen är till vänster om uppslagskolumnen som visas nedan:

I det här fallet kan du kombinera CHOOSE funktion med VLOOKUP-funktionen för att lösa problemet.

Formel:

=VLOOKUP(E1,CHOOSE({1,2},B1:B7,A1:A7),2,FALSE)

Förklara:

CHOOSE({1,2},B1:B7,A1:A7): som argument för table_range i VLOOKUP-funktionen. {1,2} betyder att visa 1 eller 2 som index_numr-argument baserat på col_num-argumentet i VLOOKUP-funktionen. Här är kolumnen i VLOOKUP-funktionen 2, så CHOOSE funktionsdisplay som CHOOSE(2, B1:B7,A1:A7), betyder att välja värde från A1: A7.

---

Ex6 - Retur vardag eller månad baserat på angivet datum

Med CHOOSE funktion kan du också returnera den relativa veckodagen och månaden baserat på ett visst datum.

Formel 1: returnera vardag med ett datum

=CHOOSE(WEEKDAY(),"Sunday","Monday","Tuesday","Wednesday","Thursday","Friday","Saturday")

Förklara:

WEEKDAY(): argumentet index_num, för att få veckodagens nummer för det angivna datumet, till exempel returnerar WEEKDAY (A5) 6, då är argumentet index_num 6.

"Sunday","Monday","Tuesday","Wednesday","Thursday","Friday","Saturday": värdelistargument, börja med "söndag" eftersom vardag "1" anger "söndag".

Formel 2: returmånad med datum

=CHOOSE(MONTH(),"Jan","Feb","Mar","Apr","May","Jun","Jul","Aug","Sep","Oct","Nov","Dec")

Förklara:

MONTH(): index_num argument, som får månadsnumret från det angivna datumet, till exempel returnerar MÅNAD (A5) 3.

---

Ex7 - Återgå till nästa arbetsdag / helgdatum baserat på idag

I det dagliga arbetet kanske du vill beräkna nästa arbetsdag eller helg baserat på idag. Här är CHOOSE funktionen kan också göra dig en tjänst.

Till exempel, idag är 12-20-2018, torsdag, nu måste du få nästa arbetsdag och helg.

Formel 1: få datumet för idag

=TODAY()

Resultat: 12-20-2018

Formel 2: få veckodag numret i dag

=WEEKDAY(TODAY())

Resultat: 5 (medan idag är 12-20-2018)

Listan över vardagar enligt nedan visad skärmdump:

Formel 3: få nästa arbetsdag

=TODAY()+CHOOSE(WEEKDAY(TODAY()),1,1,1,1,1,3,2)

Förklara:

Today(): returnera det aktuella datumet

WEEKDAY(TODAY()): index_num argument i CHOOSE funktion, få dagens veckodag, till exempel söndag är 1, måndag är 2 ...

1,1,1,1,1,3,2: värde listargument i CHOOSE fungera. Till exempel, om vardag (idag ()) returnerar 1 (söndag), väljer den 1 från värdelistan, sedan ändras hela formeln till = Idag () + 1, vilket innebär att du lägger till 1 dag för att återvända nästa måndag. Om vardag (idag ()) returnerar 6 (fredag) väljer den 3 från listan över värden, eftersom fredag ​​är 3 dagar långt från nästa måndag.

Resultat (medan idag är 12-20-2018):

=12/20/2018+CHOOSE(5,1,1,1,1,1,3,2)

= 12/20/2018 + 1

= 12/21/2018

Formel 4: få nästa helgdag

=TODAY()+CHOOSE(WEEKDAY(TODAY()),6,5,4,3,2,1,1)

Förklara:

6,5,4,3,2,1,1: värde listargument i CHOOSE fungera. Till exempel, om vardag (idag ()) returnerar 1 (söndag) väljer den 6 från värdelistan, ändras hela formeln till = idag () + 6, vilket innebär att du lägger till 6 dagar och återvänder nästa lördag.

Resultat:

=12/20/2018+CHOOSE(5,6,5,4,3,2,1,1)

= 12/20/2018 + 2

= 12/22/2018

---

Provfil