Note: The other languages of the website are Google-translated. Back to English
English English

excel SUMPRODUCT fungera

I Excel kan SUMPRODUCT-funktionen användas för att multiplicera två eller flera kolumner eller matriser tillsammans och sedan få summan av produkter. Faktum är att SUMPRODUCT är en användbar funktion som kan hjälpa till att räkna eller summera cellvärden med flera kriterier som COUNTIFS eller SUMIFS-funktionen. Den här artikeln presenterar funktionssyntaxen och några exempel för den här SUMPRODUCT-funktionen.


 Syntax:

Syntaksen för SUMPRODUCT-funktionen i Excel är:

=SUMPRODUCT (array1, [array2], ...)

 argument:

  • array1: Obligatoriskt. Den första matrisen eller det cellområde du vill multiplicera och sedan lägga till.
  • array2: Valfritt. Den andra matrisen eller cellområdet som du vill multiplicera och sedan lägga till.

Anmärkningar:

  • 1. Om det finns icke-numeriska värden i ditt intervall, behandlar SUMPRODUCT dem som nollor.
  • 2. Om matriserna eller intervallen har olika antal rader och kolumner returnerar funktionen SUMPRODUCT en #VÄRDE! fel.
  • 3. Om det finns logiska tester i matriserna kommer de att skapa SANT och FALSKA värden. I de flesta fall måste du konvertera dem till 1 och 0 med den dubbla unary-operatören (-).
  • 4. SUMPRODUCT-funktionen kan hantera upp till 255 argument i Excel 2007 och senare versioner, och endast 30 argument i tidigare Excel-versioner.
  • 5. SUMPRODUCT stöder inte jokertecken.

 Lämna tillbaka:

Returnera resultatet av multiplicerade och summerade matriser.


 Exempel:

Exempel 1: Grundläggande användning av SUMPRODUCT-funktionen

Den grundläggande användningen av SUMPRODUCT är att multiplicera två kolumner och sedan lägga till dem, till exempel har du följande skärmdumpdata, nu vill du multiplicera ordern och enhetspriset och sedan summera alla multiplicera resultaten för att få totalbelopp.

För att hantera denna uppgift, använd följande formel:

=SUMPRODUCT(B2:B7,C2:C7)

Förklaring: Denna formel SUMPRODUCT(B2:B7,C2:C7) = B2*C2+B3*C3+B4*C4+B5*C5+B6*C6+B7*C7.

Och tryck sedan på ange nyckeln multipliceras cellerna i kolumn B med motsvarande celler i samma rad i kolumn C och resultaten läggs till. Se skärmdump:


Exempel 2: Summa celler med flera kriterier med SUMPRODUCT-funktion

Med undantag för SUMIFS-funktionen för att summera cellvärden baserat på flera förhållanden kan SUMPRODUCT-funktionen också lösa detta jobb snabbt och enkelt.


Fall 1: Summa cellvärden om det innehåller specifik text i en annan kolumn

Om du antar att du har en datatabell enligt nedanstående skärmdump, nu vill du beräkna det totala priset som produkten är KTE och namnet är David. Hur kan du göra genom att använda SUMPRODUCT-formeln i Excel?

1. Ange eller kopiera någon av nedanstående formler till en tom cell:

=SUMPRODUCT(--(A2:A12="KTE"), --(B2:B12="David"), D2:D12)
=SUMPRODUCT((A2:A12="KTE")*(B2:B12="David")*D2:D12)
  • tips: I ovanstående formel:
  • A2: A12 = "KTE": är det första kriterieområdet och kriterierna du vill summera baserat på.
  • B2: B12 = "David": är det andra kriterieområdet och kriterierna du vill summera baserat på.
  • D2: D12: är det summeringsområde som du vill summera cellvärdena.

2. Tryck sedan på ange nyckel för att få resultatet efter behov:


Fall2: Summa celler med flera kriterier med ELLER-logik

För att summera celler baserat på flera kriterier med ELLER-logik, ska du använda plussymbolen (+) för att sammanfoga flera villkor i SUMPRODUCT-funktionen.

Till exempel vill jag summera det totala priset för produkten KTE och KTO i kolumn A enligt nedanstående skärmdump:

Använd följande formel i en tom cell:

=SUMPRODUCT((A2:A12="KTE")+(A2:A12="KTO"), C2:C12)

Och tryck sedan på ange nyckel, det totala priset för produkten KTE och KTO har beräknats, se skärmdump:


Case3: Summa celler med flera kriterier med OR och AND-logik

I vissa situationer kan du behöva summera celler med både OR och AND-logik samtidigt. SUMPRODUCE-funktionen kan också enkelt lösa detta jobb.

Asterisk (*) används som AND-operatör.

Plus-symbol (+) används som OR-operatör.

Låt oss se ett exempel för att summera det totala priset vilken produkt är KTE och KTO när försäljningen är större än 200.

Du bör kopiera eller ange formeln nedan:

=SUMPRODUCT((B2:B12>200)*((A2:A12="KTE")+(A2:A12="KTO"))*C2:C12)

Tryck sedan på ange nyckel för att få resultatet efter behov:


Exempel 3: Räkna celler med flera kriterier med SUMPRODUCT-funktionen

Generellt kan denna SUMPRODUCT-funktion också hjälpa oss att räkna cellerna med flera kriterier i Excel. På samma sätt som summan behöver du bara ta bort argumentet sum_range från formeln.


Fall 1: Räkna celler med flera kriterier med AND-logik

Här vill jag räkna cellerna som produkten är KTE och försäljningen är större än 200. Så använd någon av nedanstående formler:

=SUMPRODUCT(--(A2:A12="KTE"), --(B2:B12>200))
=SUMPRODUCT((A2:A12="KTE")*(B2:B12>200))
  • tips: I ovanstående formel:
  • A2: A12 = "KTE": är det första kriterieområdet och kriterierna du vill räkna utifrån.
  • B2: B12> 200: är det andra kriterieområdet och kriterierna du vill räkna utifrån.

Och tryck sedan på ange för att få resultatet av resultatet:


Fall2: Räkna celler med flera kriterier med ELLER-logik

För att räkna antalet produkter KTE och KTO i kolumn A, använd denna formel:

=SUMPRODUCT((A2:A12="KTE")+(A2:A12="KTO"))

Och tryck sedan på ange nyckel för att få numret på produkten KTE och KTO. Se skärmdump:


Case3: Räkna celler med flera kriterier med OR och AND-logik

För att räkna antalet produkter KTE och KTO där försäljningen är större än 200, bör du använda följande formel:

=SUMPRODUCT((B2:B12>200)*((A2:A12="KTE")+(A2:A12="KTO")))

Tryck sedan på ange för att få det antal resultat du behöver:


Exempel 4: Beräkna det vägda genomsnittet med SUMPRODUCT-funktionen

Normalt kan vi snabbt och enkelt beräkna genomsnittet av cellområdet. Men om du vill beräkna genomsnittet av en lista med värden med olika nivåer av relevans, betyder det att beräkna det vägda genomsnittet. Det finns ingen direkt funktion för att få den i Excel. Men SUMPRODUCT-funktionen kan hjälpa dig att hantera det.

Till exempel har jag en tabell över betygsstatistik för en elev, varje uppgift har olika vikt enligt nedanstående skärmdump.

För att beräkna det vägda genomsnittet, använd följande formel:

=SUMPRODUCT(B2:B6, C2:C6) / SUM(C2:C6)

Förklaring: Denna formel: SUMPRODUCT(B2:B6, C2:C6) / SUM(C2:C6) = (B2*C2+B3*C3+B4*C4+B5*C5+B6*C6)/(C2+C3+C4+C5+C6)

Och tryck sedan på ange nyckel, det vägda genomsnittet har beräknats på en gång, se skärmdump:


 Fler artiklar med SUMPRODUCT-funktion:

  • Countif Ett specifikt värde över flera arbetsblad
  • Antag att jag har flera kalkylblad som innehåller följande data, och nu vill jag få antalet förekomster av ett specifikt värde "Excel" från avhandlingens kalkylblad. Hur kunde jag räkna specifika värden i flera kalkylblad?
  • Beräkna viktat genomsnitt i Excel
  • Du har till exempel en inköpslista med priser, vikter och belopp. Du kan enkelt beräkna genomsnittspriset med AVERAGE-funktionen i Excel. Men vad händer om vägt genomsnittspris? I den här artikeln kommer jag att introducera en metod för att beräkna det vägda genomsnittet, samt en metod för att beräkna det vägda genomsnittet om de uppfyller specifika kriterier i Excel.

De bästa Office-produktivitetsverktygen

Kutools för Excel - Hjälper dig att sticka ut från mängden

Vill du slutföra ditt dagliga arbete snabbt och perfekt? Kutools för Excel ger 300 kraftfulla avancerade funktioner (kombinera arbetsböcker, summera efter färg, dela cellinnehåll, konvertera datum och så vidare ...) och spara 80% tid åt dig.

  • Designad för 1500 arbetsscenarier, hjälper dig att lösa 80% Excel-problem.
  • Minska tusentals tangentbord och musklick varje dag, lindra dina trötta ögon och händer.
  • Bli en expert på 3 minuter. Behöver inte längre komma ihåg några smärtsamma formler och VBA-koder.
  • 30 dagars obegränsad gratis provperiod. 60-dagars pengarna tillbaka-garanti. Gratis uppgradering och support i 2 år.
Ribbon of Excel (med Kutools för Excel installerat)

Fliken Office - Aktivera läsning och redigering av flikar i Microsoft Office (inkluderar Excel)

  • En sekund att växla mellan dussintals öppna dokument!
  • Minska hundratals musklick åt dig varje dag, säg adjö till mushanden.
  • Ökar din produktivitet med 50% när du tittar på och redigerar flera dokument.
  • Ger effektiva flikar till Office (inkluderar Excel), precis som Chrome, Firefox och ny Internet Explorer.
Skärmdump av Excel (med Office-fliken installerad)
Sortera kommentarer efter
Kommentarer (0)
Inga betyg än. Bli först med att betygsätta!
Det finns inga kommentarer här ännu
Lämna dina kommentarer
Postar som gäst
×
Betygsätt detta inlägg:
0   Tecken
Föreslagna platser