I Excel, medan IF-funktionen är väsentlig för grundläggande logiska tester, kräver komplexa förhållanden ofta kapslade IF-satser för förbättrad databehandling. I den här omfattande guiden kommer vi att täcka grunderna för kapslade IF i detalj, från syntax till praktiska tillämpningar, inklusive kombinationer av kapslade IF med OCH/ELLER-villkor. Dessutom kommer vi att dela med oss ​​av hur man kan förbättra läsbarheten för kapslade IF-funktioner samt några tips om kapslade IF, och utforska kraftfulla alternativ som VLOOKUP, IFS och mer för att göra komplexa logiska operationer enklare att använda och effektivare.

• Syntax för kapslad IF
• Praktiska exempel på kapslade IF
• Kapslad om med OCH/ELLER-villkor

• Gör kapslade IF lätt att läsa
• Ordningen på kapslade IF-funktioner
• Siffror och text bör behandlas olika
• Begränsningar för kapslade IF

• Använder VLOOKUP
• Använder IFS
• Använder VÄLJ och MATCH

Excel IF-funktion kontra kapslade IF-satser

IF-funktionen och kapslade IF-satser i Excel har liknande syften men skiljer sig avsevärt i sin komplexitet och tillämpning.

Användning av kapslade IF

Det här avsnittet visar den grundläggande användningen av kapslade IF-satser i Excel, inklusive syntax, praktiska exempel och hur man använder dem med OCH- eller ELLER-villkor.

Syntax för kapslad IF

Att förstå syntaxen för en funktion är grunden för dess korrekta och effektiva tillämpning i Excel. Låt oss börja med syntaxen för kapslade if-satser.

syntax:

=IF(condition1, result1, IF(condition2, result2, IF(condition3, result3, result4)))

Argument:

• Condition1, Condition2, Condition3: These are the conditions you want to test. Each condition is evaluated in order, starting with Condition1.
• Result1: This is the value returned if Condition1 is TRUE.
• Result2: This value is returned if Condition1 is FALSE and Condition2 is TRUE. It's important to note that Result2 is only evaluated if Condition1 is FALSE.
• Result3: This value is returned if both Condition1 and Condition2 are FALSE, and Condition3 is TRUE. Essentially, for Result3 to be evaluated, the previous conditions (Condition1 and Condition2) must both be FALSE.
• Result4: This result is returned if all the conditions (Condition1, Condition2, and Condition3) are FALSE.
  
  In short, this expression can be interpreted as follows:
  Test condition1, if TRUE, return result1, if FALSE,
  test condition2, if TRUE, return result2, if FALSE,
  test condition3, if TRUE, return result3, if FALSE,
  return result4

Kom ihåg att i en kapslad IF-struktur utvärderas varje efterföljande villkor endast om alla tidigare villkor är FALSKA. Denna sekventiella kontroll är avgörande för att förstå hur kapslade IF:er fungerar.

Praktiska exempel på kapslade IF

Låt oss nu dyka in i användningen av kapslade IF med två praktiska exempel.

Exempel 1: Betygssystem

Som visas i skärmdumpen nedan, anta att du har en lista med elevpoäng och vill ge betyg baserat på dessa poäng. Du kan använda kapslade IF för att utföra denna uppgift.

Välj en tom cell (C2 i det här fallet), skriv in följande formel och tryck ange för att få resultatet. Dra sedan Fyll handtaget ner för att få resten av resultaten.

=IF(B2>=90,$F$2,IF(B2>=80,$F$3,IF(B2>=70,$F$4,IF(B2>=60,$F$5,$F$6))))

Exempel 2: Beräkning av försäljningsprovision

Föreställ dig ett scenario där säljare får olika provisionssatser baserat på deras försäljningsprestationer. Som visas i skärmdumpen nedan vill du beräkna provisionen för en säljare baserat på dessa olika försäljningströsklar, och kapslade IF-uttalanden kan hjälpa dig med detta.

Välj en tom cell (C2 i det här fallet), skriv in följande formel och tryck ange för att få resultatet. Dra sedan Fyll handtaget ner för att få resten av resultaten.

=B2*IF(B2>20000,$F$2,IF(B2>=10000,$F$3,$F$4))

Kapslad om med OCH/ELLER-villkor

I det här avsnittet ändrar jag ovanstående första exempel "betygssystemet" för att visa hur man kombinerar kapslade OM med OCH- eller ELLER-villkor i Excel. I det reviderade betygsexemplet införde jag ytterligare ett villkor baserat på "Närvarograd".

Använder kapslade om med AND-villkor

Om en elev uppfyller både poäng- och närvarokriterierna får de en betygshöjning. Till exempel, en student vars poäng är 60 eller högre och vars närvarofrekvens är 95 % eller högre kommer att få sitt betyg uppgraderat med en nivå, till exempel från A till A+, B till B+ och så vidare. Men om närvarofrekvensen är under 95 % kommer betyget att följa de ursprungliga poängbaserade kriterierna. I sådana fall måste vi använda en kapslad IF-sats med ett AND-villkor.

Välj en tom cell (D2 i det här fallet), skriv in följande formel och tryck ange för att få resultatet. Dra sedan Fyll handtaget ner för att få resten av resultaten.

=IF(AND(B2>=60, C2>=95%),IF(B2>=90, "A+", IF(B2>=80, "B+", IF(B2>=70, "C+", "D+"))),IF(B2>=90, "A", IF(B2>=80, "B", IF(B2>=70, "C", IF(B2>=60, "D", "F")))))

Använder kapslade om med OR-villkor

I det här fallet kommer en elevs betyg att höjas en nivå om deras poäng är 95 eller högre, eller om deras närvarofrekvens är 95 % eller mer. Så här kan vi åstadkomma det med kapslade OM- och ELLER-villkor.

Välj en tom cell (D2 i det här fallet), skriv in följande formel och tryck ange för att få resultatet. Dra sedan Fyll handtaget ner för att få resten av resultaten.

=IF(OR(B2>=95, C2>=95%),IF(B2>=90, "A+", IF(B2>=80, "B+", IF(B2>=70, "C+", IF(B2>=60, "D+", "F+")))),IF(B2>=90, "A", IF(B2>=80, "B", IF(B2>=70, "C", IF(B2>=60, "D", "F")))))

Tips och tricks för kapslade IF

Det här avsnittet täcker fyra användbara tips och tricks för kapslade IF.

Gör kapslade IF lätt att läsa

En typisk kapslad IF-sats kan se kompakt ut men kan vara svår att tyda.

I följande formel är det utmanande att snabbt identifiera var ett tillstånd slutar och ett annat börjar, särskilt när komplexiteten ökar.

=IF(A2>=90, "A", IF(A2>=80, "B", IF(A2>=70, "C", IF(A2>=60, "D", "F"))))

Lösning: Lägga till radbrytningar och indrag

För att göra kapslade IF lätt att läsa kan du dela upp formeln i flera rader med varje kapslad IF på en ny rad. I formeln placerar du bara markören före IF och trycker på Alt + Enter.

Efter att ha brutit formeln ovan visas den enligt följande:

=IF(A2>=90, "A",
      IF(A2>=80, "B",
          IF(A2>=70, "C",
              IF(A2>=60, "D", "F")))
)

Detta format gör det tydligare var varje villkor och motsvarande utdata finns, vilket förbättrar formelns läsbarhet.

Ordningen på kapslade IF-funktioner

Ordningen för logiska villkor i en kapslad IF-formel är avgörande eftersom den bestämmer hur Excel utvärderar dessa villkor och därmed påverkar det slutliga resultatet av formeln.

Rätt formel

I exemplet med betygssystem använder vi följande formel för att tilldela betyg baserat på poäng.

=IF(B2>=90, "A", IF(B2>=80, "B", IF(B2>=70, "C", IF(B2>=60, "D", "F"))))

Excel utvärderar villkoren i en kapslad IF-formel sekventiellt, från det första villkoret till det sista. Denna formel kontrollerar först tröskeln för högsta poäng (>=90 för ett "A") och flyttar sedan till de lägre tröskelvärdena. Det säkerställer att ett betyg jämförs med det högsta betyget det kvalificerar sig för. Om det första villkoret är sant (A2>=90), returnerar det "A" och utvärderar inga ytterligare villkor.

Felaktig ordnad formel

Om ordningen på villkoren var omvänd, med början med den lägsta tröskeln, skulle det returnera felaktiga resultat.

=IF(B2>=60, "D", IF(B2>=70, "C", IF(B2>=80, "B", IF(B2>=90, "A", "F"))))

I denna felaktiga formel skulle en poäng på 95 omedelbart uppfylla det första villkoret B2>=60 och felaktigt tilldelas betyget "D".

Siffror och text bör behandlas olika

Det här avsnittet visar hur siffror och text behandlas olika i kapslade IF-satser.

Nummer

Siffror används för aritmetiska jämförelser och beräkningar. I kapslade IF-satser kan du direkt jämföra tal med operatorer som >, <, =, >= och <=.

text

I kapslade IF-satser ska texten vara omges av dubbla citattecken. Se A, B, C, D och F i följande formel:

=IF(A2>=90, "A", IF(A2>=80, "B", IF(A2>=70, "C", IF(A2>=60, "D", "F"))))

Begränsningar för kapslade IF

Det här avsnittet listar flera begränsningar och nackdelar med kapslade IF.

Komplexitet och läsbarhet:

Även om Excel tillåter dig att kapsla upp till 64 olika IF-funktioner, är det inte alls tillrådligt att göra det. Ju fler nivåer av häckning, desto mer komplex blir formeln. Detta kan leda till formler som är svåra att läsa, förstå och underhålla.

Felbenägen:

Dessutom kan komplexa kapslade IF-satser bli benägna för fel och utmanande att felsöka eller ändra.

Svårt att utöka eller skala:

Om din logik ändras eller om du behöver lägga till fler villkor kan djupt kapslade IF:er vara svåra att ändra eller utöka.

Att förstå dessa begränsningar är nyckeln till att använda kapslade IF-satser effektivt i Excel. Ofta kan en kombination av kapslade IF:er med andra funktioner eller söka alternativa tillvägagångssätt leda till mer effektiva och underhållbara lösningar.

Alternativ till Nested IF

Det här avsnittet listar flera funktioner i Excel som kan användas som alternativ till kapslade IF-satser.

Använder VLOOKUP

Du kan använda VLOOKUP-funktionen istället för kapslade IF-satser för att utföra ovanstående två praktiska exempel. Så här kan du göra det:

Exempel 1: Betygssystem med VLOOKUP

Här kommer jag att visa hur man använder VLOOKUP för att ge betyg baserat på poäng.

Steg 1: Skapa en uppslagstabell för betyg

Först måste du skapa en uppslagstabell (som E1:F6 i det här fallet) för poängintervallet och motsvarande betyg. Anmärkningar: Poäng i den första kolumnen i tabellen måste sorteras i stigande ordning.

Steg 2: Använd VLOOKUP-funktionen för att ge betyg

Välj en tom cell (C2 i det här fallet), ange följande formel och tryck på ange nyckeln för att få första betyget. Välj den här formelcellen och dra dess Fyll handtaget ner för att få resten av betygen.

=VLOOKUP(B2,$E$2:$F$6,2,TRUE)

Exempel 2: Beräkning av försäljningsprovision med VLOOKUP

Du kan också använda VLOOKUP för att utföra beräkningen av försäljningsprovisionen i Excel. Vänligen gör enligt följande.

Steg 1: Skapa en uppslagstabell för betyg

Först måste du skapa en uppslagstabell för försäljningen och motsvarande provisionssats, som E2:F4 i detta fall. Anmärkningar: Försäljningen i den första kolumnen i tabellen måste sorteras i stigande ordning.

Steg 2: Använd VLOOKUP-funktionen för att ge betyg

Välj en tom cell (C2 i det här fallet), skriv in följande formel och tryck på Enter för att få den första provisionen. Välj den här formelcellen och dra dess fyllningshandtag nedåt för att få resten av resultaten.

=B2*VLOOKUP(B2,$E$2:$F$4,2,TRUE)

Använder IFS

Smakämnen IFS-funktion förenklar processen genom att eliminera behovet av kapsling och gör formlerna lättare att läsa och hantera. Det förbättrar läsbarheten och effektiviserar hanteringen av flera villkorade kontroller. För att använda IFS-funktionen, se till att du använder Excel 2019 eller senare, eller har en Office 365-prenumeration. Låt oss se hur det kan tillämpas i praktiska exempel.

Exempel 1: Betygssystem med IFS

Med samma betygskriterier som tidigare kan IFS-funktionen användas enligt följande:

Välj en tom cell, till exempel C2, ange följande formel och tryck ange för att få det första resultatet. Välj denna resultatcell och dra dess Fyll handtaget ner för att få resten av resultaten.

=IFS(B2>=90,"A",B2>=80,"B",B2>=70,"C",B2>=60,"D",B2<60,"F")

Exempel 2: Försäljningsprovisionsberäkning med IFS

För beräkningsscenariot för försäljningsprovision tillämpas IFS-funktionen enligt följande:

Välj en tom cell, till exempel C2, ange följande formel och tryck ange för att få det första resultatet. Välj denna resultatcell och dra dess Fyll handtaget ner för att få resten av resultaten.

=B2*IFS(B2>20000,20%,B2>=10000,15%,TRUE,10%)

Använder VÄLJ och MATCH

Tillvägagångssättet CHOOSE och MATCH kan vara effektivare och lättare att hantera jämfört med kapslade IF-satser. Denna metod förenklar formeln och gör uppdateringar eller ändringar enklare. Nedan kommer jag att visa hur man använder en kombination av funktionerna VÄLJ och MATCH för att hantera de två praktiska exemplen i den här artikeln.

Exempel 1: Betygssystem med CHOOSE och MATCH

Du kan använda kombinationen av funktionerna CHOOSE och MATCH för att ge betyg baserat på olika poäng.

Steg 1: Skapa en uppslagsmatris med sökvärden

Först måste du skapa ett intervall av celler som innehåller tröskelvärdena som MATCH kommer att söka igenom, till exempel $E$2:$E$6 i detta fall. Anmärkningar: Siffrorna i detta intervall måste sorteras i stigande ordning för att MATCH-funktionen ska fungera korrekt när en ungefärlig matchningstyp används.

Steg 2: Använd CHOOSE och MATCH för att ge betyg

Välj en tom cell (C2 i det här fallet), ange följande formel och tryck på ange nyckeln för att få första betyget. Välj den här formelcellen och dra dess Fyll handtaget ner för att få resten av resultaten.

=CHOOSE(MATCH(B2, $E$2:$E$6, 1), "F", "D", "C", "B", "A")

Exempel 2: Försäljningsprovisionsberäkning med IFS

Att använda kombinationen VÄLJ och MATCH för en försäljningsprovisionsberäkning kan också vara effektivt, särskilt när provisionssatserna baseras på specificerade försäljningströsklar. Låt oss se hur vi kan göra.

Steg 1: Skapa en uppslagsmatris med sökvärden

Först måste du skapa ett intervall av celler som innehåller tröskelvärdena som MATCH kommer att söka igenom, till exempel $E$2:$E$4 i detta fall. Anmärkningar: Siffrorna i detta intervall måste sorteras i stigande ordning för att MATCH-funktionen ska fungera korrekt när en ungefärlig matchningstyp används.

Steg 2: Använd CHOOSE och MATCH för att få resultaten

Välj en tom cell (C2 i det här fallet), ange följande formel och tryck på ange nyckeln för att få första betyget. Välj den här formelcellen och dra dess Fyll handtaget ner för att få resten av resultaten.

=B2*CHOOSE(MATCH(B2, $E$2:$E$4, 1), 10%, 15%, 20%)

Sammanfattningsvis är att bemästra kapslade IF-satser i Excel en värdefull färdighet som förbättrar din förmåga att hantera komplexa logiska scenarier i dataanalys och beslutsprocesser. Även om kapslade IF:er är kraftfulla för komplexa logiska operationer, är det viktigt att vara uppmärksam på deras begränsningar. Enklare alternativ som VLOOKUP, IFS och CHOOSE med MATCH kan ge mer strömlinjeformade lösningar i vissa scenarier. Beväpnad med dessa insikter kan du nu med säkerhet tillämpa de mest lämpliga Excel-teknikerna på dina dataanalysuppgifter, vilket säkerställer tydlighet, noggrannhet och effektivitet i dina kalkylblad. För dem som är ivriga att fördjupa sig i Excels möjligheter, har vår webbplats en mängd handledningar. Upptäck fler Excel-tips och tricks här.

Relaterade artiklar