Extrahera filnamn från en sökväg i Excel
Den här handledningen förklarar hur man använder formler för att extrahera filnamn med eller utan förlängning från en sökväg i en specifik cell i Excel.
Extrahera filnamn med tillägg från en sökväg
Extrahera filnamn utan förlängning från en sökväg
Extrahera filnamn med tillägg från en sökväg
Som skärmbilden nedan visas finns det en lista som innehåller olika filsökvägar, och du vill bara extrahera filnamnen med tillägg från dem, följande formel hjälper dig att lösa problemet.
Generisk formel
=MID(A1,FIND("*",SUBSTITUTE(A1,"\","*",LEN(A1)-LEN(SUBSTITUTE(A1,"\",""))))+1,LEN(A1))
Argument
A1: Representerar cellen som innehåller filsökvägen du kommer att extrahera filnamnet från den.
Hur använder jag den här formeln?
1. Välj en tom cell för att mata ut filnamnet. I det här fallet väljer jag cellen D3.
2. Ange formeln nedan och tryck på ange nyckel. Markera resultatcellen och dra sedan dess fyllningshandtag hela vägen ned för att tillämpa den på andra celler.
=MID(B3,FIND("*",SUBSTITUTE(B3,"\","*",LEN(B3)-LEN(SUBSTITUTE(B3,"\",""))))+1,LEN(B3))
Nu extraheras alla filnamn med tillägg i specifika filsökvägar som skärmdumpen ovan visas.
Anmärkningar:
- I den här formeln är B3 cellen som innehåller filsökvägen. Vänligen ändra det efter behov.
- Om filnamnet inte är mer än 99 tecken långt, kan nedanstående kortare formel också användas för att lösa problemet. Se nedanstående skärmdump.
=TRIM(RIGHT(SUBSTITUTE(A2,"\",REPT(" ",100)),99))
Hur fungerar denna formel?
=MID(B3,FIND("*",SUBSTITUTE(B3,"\","*",LEN(B3)-LEN(SUBSTITUTE(B3,"\",""))))+1,LEN(B3))
1. FIND("*",SUBSTITUTE(B3,"\","*",LEN(B3)-LEN(SUBSTITUTE(B3,"\",""))))
- LEN(B3): LEN-funktionen beräknar den totala längden i "D:\\files\work\Q1\Jan\text.txt" och returnerar resultatet som 30;
- LEN(SUBSTITUTE(B3,"\","")): ERSÄTTNINGSfunktionen ersätter tecknet "\" med ingenting. Resultatet är "D:filesworkQ1Jantext.txt". Och sedan beräknar LEN-funktionen den totala längden av "D:filesworkQ1Jantext.txt" och får resultatet 24;
- SUBSTITUTE(B3,"\","*",30-24): ERSÄTTNINGSfunktionen ersätter det tredje tecknet (30-24=6) "\" i "D:\\files\work\Q1\Jan\text.txt" med ett enda tecken "*". Här är resultatet "D:\\files\work\Q1\Jan*text.txt";
- FIND("*","D:\\files\work\Q1\Jan*text.txt"): Funktionen FIND lokaliserar positionen för tecknet "*" i "D:\\files\work\Q1\Jan*text.txt" och returnerar slutligen 22. Här betyder att tecknet "*" är på 22:e positionen i " D:\\filer\arbete\Q1\Jan*text.txt".
2. =MID(B3,22+1,LEN(B3))
- Som förklaringen ovan visas, returnerar LEN(B3) resultatet som 30, här kan MID-funktionen visas som =MID("D:\\filer\arbete\Q1\Jan\text.txt",23,30). Det betyder att MID-funktionen extraherar 30 tecken från strängen "D:\\files\work\Q1\Jan\text.txt", med början på det 23:e tecknet. Här är resultatet text.txt.
Extrahera filnamn utan förlängning från en sökväg
En annan omständighet, du kanske bara behöver extrahera filnamnet utan förlängning från en sökväg som skärmdumpen nedan visas. Det här avsnittet kommer att ge en lång formel som hjälper dig att få ner det.
Generisk formel
=IFERROR(MID(A1,FIND(CHAR(1),SUBSTITUTE(A1,"\",CHAR(1),LEN(A1)-LEN(SUBSTITUTE(A1,"\",""))))+1,FIND(CHAR(1),SUBSTITUTE(A1,".",CHAR(1),LEN(A1)-LEN(SUBSTITUTE(A1,".",""))))-FIND(CHAR(1),SUBSTITUTE(A1,"\",CHAR(1),LEN(A1)-LEN(SUBSTITUTE(A1,"\",""))))-1),"")
Argument
A1: Representerar cellen som innehåller filsökvägen du kommer att extrahera filnamnet från den.
CHAR (1): CHAR(1) här kan ersättas med valfritt CHAR-nummer som du behöver. Eller så kan den ersättas med en specifik symbol inom citattecken som "*".
Hur använder jag den här formeln?
1. Välj en tom cell för att mata ut filnamnet utan tillägget.
2. Ange formeln nedan och tryck på ange nyckel. Markera resultatcellen och dra sedan dess fyllningshandtag hela vägen ned för att tillämpa den på andra celler.
=IFERROR(MID(B4,FIND(CHAR(1),SUBSTITUTE(B4,"\",CHAR(1),LEN(B4)-LEN(SUBSTITUTE(B4,"\",""))))+1,FIND(CHAR(1),SUBSTITUTE(B4,".",CHAR(1),LEN(B4)-LEN(SUBSTITUTE(B4,".",""))))-FIND(CHAR(1),SUBSTITUTE(B4,"\",CHAR(1),LEN(B4)-LEN(SUBSTITUTE(B4,"\",""))))-1),"")
Anmärkningar: I den här formeln är B3 cellen som innehåller filsökvägen. Vänligen ändra det efter behov.
Relaterade funktioner
Excel MID-funktion
Excel MID-funktionen används för att hitta och returnera ett visst antal tecken från mitten av en given textsträng.
Excel HITTA-funktion
Excel FIND-funktionen används för att hitta en sträng i en annan sträng och returnerar startpositionen för strängen i en annan sträng.
Excel SUBSTITUTE-funktion
Excel SUBSTITUTE-funktionen ersätter text eller tecken i en textsträng med en annan text eller andra tecken.
Excel LEN-funktion
Excel LEN-funktionen returnerar antalet tecken i en textsträng.
Excel IFERROR-funktion
IFERROR-funktionen används för att returnera ett anpassat resultat när en formel utvärderar ett fel och returnera ett normalt resultat när inget fel inträffar.
Relaterade formler
Extrahera flera linjer från en cell
Om du har en lista med textsträngar som är åtskilda av radbrytningar (som sker genom att trycka på Alt + Enter när du skriver in texten), och vill extrahera dessa textrader i flera celler, kommer formeln i den här handledningen att göra dig en förmån.
Extrahera den sista raden av text från en cell med flera rader
För att extrahera den sista textraden från en textsträng som är separerad av radbrytningar, kan en formel i denna handledning hjälpa dig att hantera den här uppgiften i Excel.
Extrahera Nth Word från textsträng i Excel
Den här artikeln förklarar hur du använder en formel för att extrahera det specifika n:te ordet från en textsträng i en cell i Excel.
Extrahera de två sista orden från en cell i Excel
Denna handledning förklarar hur man använder formel för att extrahera de två sista orden från en cell i Excel.
Extrahera ord som börjar med ett specifikt tecken i Excel
Denna handledning tillhandahåller en formel med detaljerade steg som hjälper dig att extrahera ordet som börjar med ett specifikt tecken från en textsträng i en cell i Excel.
Extrahera alla ord men först eller sist
I den här handledningen kommer du att lära dig hur du använder formler för att extrahera alla ord från en cell utom det första eller sista i Excel.
De bästa Office-produktivitetsverktygen
Kutools for Excel - Hjälper dig att sticka ut från mängden
Kutools for Excel har över 300 funktioner, Se till att det du behöver bara är ett klick bort...
Office Tab - Aktivera flikläsning och redigering i Microsoft Office (inklusive Excel)
- En sekund att växla mellan dussintals öppna dokument!
- Minska hundratals musklick åt dig varje dag, säg adjö till mushanden.
- Ökar din produktivitet med 50 % när du visar och redigerar flera dokument.
- Ger effektiva flikar till Office (inklusive Excel), precis som Chrome, Edge och Firefox.
